#!/usr/bin/gnuplot
##########################################################################
#                           TP4 - Fisica II                              #
##########################################################################
#                                                                        #
#          Variacion de la resistencia con la temperatura.               #
#                                                                        #
##########################################################################
# Script para gnuplot para graficar esta variacion                       #
##########################################################################

################### RELACION ENTRE R Y T (To=293) ########################

# Setea la terminal como postscript para generar la salida.
set terminal postscript enhanced color

# Dibuja la referencia de las funciones abajo
set key bottom spacing 2.5

# Setea el archivo de salida
set output 'tp2-To=293.ps'

# Define la función con las que aproxima por medio de cuadrados mínimos
r(x) = a*x + b

# Setea el formato de la salida
set format xy "%g"
set title "Variacion de la resistencia con la temperatura para T_{0}=293K"
set xlabel "T (temperatura)"
set ylabel "R (resistencia)"

# Calcula la recta que mas se aproxima a los puntos por cuadrados mínimos
# teniendo en cuenta los errores
fit r(x) 'tp2.dat' using 13:7:9 via a, b

# Funciones calculada a partir de una serie de Taylor
R(x)  = -0.142 + 2.53e-3*x

# Dibuja los puntos y la recta
plot  "tp2.dat" using 13:7:($13+$14):($13-$14):($7+$8):($7-$8) title "Mediciones con sus errores" with xyerrorbars, \
      r(x) title "Recta que mejor se aproxima por cuadrados minimos: R_{(T)} = 2,94e^{-3}*T - 1,48", \
      R(x) title "Recta calculada a partir de la serie de Taylor en T_{0}=293K: R_{(T)} = 2,53e^{-3}*T - 0,14"

################### RELACION ENTRE R Y T (To=2553) #######################

# Setea la terminal como postscript para generar la salida.
set terminal postscript enhanced color

# Setea el archivo de salida
set output 'tp2-To=2553.ps'

# Define la función con las que aproxima por medio de cuadrados mínimos
r(x) = a*x + b

# Setea el formato de la salida
set format xy "%g"
set title "Variacion de la resistencia con la temperatura para T_{0}=2553K"
set xlabel "T (temperatura)"
set ylabel "R (resistencia)"

# Calcula la recta que mas se aproxima a los puntos por cuadrados mínimos
# teniendo en cuenta los errores (desde el dato 1 hasta el 10)
fit r(x) 'tp2.dat' every ::0::9 using 13:7:9 via a, b

# Funciones calculada a partir de una serie de Taylor
R(x) =  -1.57 + 3.01e-3*x

# Dibuja los puntos y la recta
plot  "tp2.dat" every ::0::9 using 13:7:($13+$14):($13-$14):($7+$8):($7-$8) title "Mediciones con sus errores" with xyerrorbars, \
      r(x) title "Recta que mejor se aproxima por cuadrados minimos: R_{(T)} = 2,94e^{-3}*T - 1,48", \
      R(x) title "Recta calculada a partir de la serie de Taylor en T_{0}=2553K: R_{(T)} = 3,01e^{-3}*T - 1,57"