#!/usr/bin/gnuplot
# vim: set tabstop=4 softtabstop=4 shiftwidth=4 expandtab:
#
# Trabajo Práctico II de Análisis Numérico I
# Genera gráficos con los resultados de las corridas utilizando
# GNU Plot.
# Copyright (C) 2002 Leandro Lucarella <leandro@lucarella.com.ar>
#
# Este programa es Software Libre; usted puede redistribuirlo
# y/o modificarlo bajo los términos de la "GNU General Public
# License" como lo publica la "FSF Free Software Foundation",
# o (a su elección) de cualquier versión posterior.
#
# Este programa es distribuido con la esperanza de que le será
# útil, pero SIN NINGUNA GARANTIA; incluso sin la garantía
# implícita por el MERCADEO o EJERCICIO DE ALGUN PROPOSITO en
# particular. Vea la "GNU General Public License" para más
# detalles.
#
# Usted debe haber recibido una copia de la "GNU General Public
# License" junto con este programa, si no, escriba a la "FSF
# Free Software Foundation, Inc.", 59 Temple Place - Suite 330,
# Boston, MA  02111-1307, USA.
#
# $URL$
# $Date$
# $Rev$
# $Author$
#

# Seteo terminal para que "dibuje" en un PS.
set term postscript eps enhanced color
set encoding iso_8859_1
set output "d4r.eps"

# Seteos generales.
set title "Estimación del tiempo de reposo para RK4 en el caso sin depósitos y con fricción laminar"
set key right top

# Eje X.
set xlabel  "Tiempo (t)"
set xrange  [0:90000]
set mxtics  5

# Eje Y.
set ylabel "Altura (z)"
set mytics  5

# Primero aproximo por una recta para hallar valores aproximados de los parámetros.
M(x) = a - b * x
m(x) = -c - d * x
fit M(x) 'd3r.max.txt' using 1:2 via a, b
fit m(x) 'd3r.min.txt' using 1:2 via c, d

# Ahora ahora la verdadera aproximación con una exponencial.
M(x) = a * exp( -b * x )
m(x) = -c * exp( -d * x )
fit M(x) 'd3r.max.txt' using 1:2 via a, b
fit m(x) 'd3r.min.txt' using 1:2 via c, d

# Plotea
plot M(x) title "Función aproximante de máximos" with lines linetype 1, \
     m(x) title "Función aproximante de mínimos" with lines linetype 8

# Se muestran las funciones aproximantes utilizadas.
print "Funciones aproximantes:"
print "M(x) = ", a, " * exp( -", b, " * x )"
print "m(x) = -", c, " * exp( -", d, " * x )"