gc/bits.d

   1 /**
   2  * This module contains a specialized bitset implementation.
   3  *
   4  * Copyright: Copyright (C) 2005-2006 Digital Mars, www.digitalmars.com.
   5  *            All rights reserved.
   6  * License:
   7  *  This software is provided 'as-is', without any express or implied
   8  *  warranty. In no event will the authors be held liable for any damages
   9  *  arising from the use of this software.
  10  *
  11  *  Permission is granted to anyone to use this software for any purpose,
  12  *  including commercial applications, and to alter it and redistribute it
  13  *  freely, in both source and binary form, subject to the following
  14  *  restrictions:
  15  *
  16  *  o  The origin of this software must not be misrepresented; you must not
  17  *     claim that you wrote the original software. If you use this software
  18  *     in a product, an acknowledgment in the product documentation would be
  19  *     appreciated but is not required.
  20  *  o  Altered source versions must be plainly marked as such, and must not
  21  *     be misrepresented as being the original software.
  22  *  o  This notice may not be removed or altered from any source
  23  *     distribution.
  24  * Authors:   Walter Bright, David Friedman, Sean Kelly
  25  */
  26
  27 module gc.bits;
  28
  29 import tango.core.BitManip;
  30 import tango.stdc.string;
  31 import tango.stdc.stdlib;
  32
  33 private extern (C) void onOutOfMemoryError();
  34
  35
  36 version (DigitalMars)
  37 {
  38     version = bitops;
  39 }
  40 else version (GNU)
  41 {
  42     // use the unoptimized version
  43 }
  44 else version(LDC)
  45 {
  46     // ditto
  47 }
  48 else version (D_InlineAsm_X86)
  49 {
  50     version = Asm86;
  51 }
  52
  53 struct GCBits
  54 {
  55     const int BITS_PER_WORD = 32;
  56     const int BITS_SHIFT = 5;
  57     const int BITS_MASK = 31;
  58
  59     uint*  data = null;
  60     size_t nwords = 0;    // allocated words in data[] excluding sentinals
  61     size_t nbits = 0;     // number of bits in data[] excluding sentinals
  62
  63     void Dtor()
  64     {
  65         if (data)
  66         {
  67             free(data);
  68             data = null;
  69         }
  70     }
  71
  72     invariant
  73     {
  74         if (data)
  75         {
  76             assert(nwords * data[0].sizeof * 8 >= nbits);
  77         }
  78     }
  79
  80     void alloc(size_t nbits)
  81     {
  82         this.nbits = nbits;
  83         nwords = (nbits + (BITS_PER_WORD - 1)) >> BITS_SHIFT;
  84         data = cast(uint*)calloc(nwords + 2, uint.sizeof);
  85         if (!data)
  86             onOutOfMemoryError();
  87     }
  88
  89     uint test(size_t i)
  90     in
  91     {
  92         assert(i < nbits);
  93     }
  94     body
  95     {
  96         //return (cast(bit *)(data + 1))[i];
  97         return data[1 + (i >> BITS_SHIFT)] & (1 << (i & BITS_MASK));
  98     }
  99
 100     void set(size_t i)
 101     in
 102     {
 103         assert(i < nbits);
 104     }
 105     body
 106     {
 107         //(cast(bit *)(data + 1))[i] = 1;
 108         data[1 + (i >> BITS_SHIFT)] |= (1 << (i & BITS_MASK));
 109     }
 110
 111     void clear(size_t i)
 112     in
 113     {
 114         assert(i < nbits);
 115     }
 116     body
 117     {
 118         //(cast(bit *)(data + 1))[i] = 0;
 119         data[1 + (i >> BITS_SHIFT)] &= ~(1 << (i & BITS_MASK));
 120     }
 121
 122     uint testClear(size_t i)
 123     {
 124         version (bitops)
 125         {
 126             return std.intrinsic.btr(data + 1, i);
 127         }
 128         else version (Asm86)
 129         {
 130             asm
 131             {
 132                 naked                   ;
 133                 mov     EAX,data[EAX]   ;
 134                 mov     ECX,i-4[ESP]    ;
 135                 btr     4[EAX],ECX      ;
 136                 sbb     EAX,EAX         ;
 137                 ret     4               ;
 138             }
 139         }
 140         else
 141         {   uint result;
 142
 143             //result = (cast(bit *)(data + 1))[i];
 144             //(cast(bit *)(data + 1))[i] = 0;
 145
 146             uint* p = &data[1 + (i >> BITS_SHIFT)];
 147             uint  mask = (1 << (i & BITS_MASK));
 148             result = *p & mask;
 149             *p &= ~mask;
 150             return result;
 151         }
 152     }
 153
 154     void zero()
 155     {
 156         version(MEMCPY_NON_SIG_SAFE) {
 157             uint * d1=data+1,dEnd=d1+nwords;
 158             for (;d1!=dEnd;++d1)
 159                 *d1=0u;
 160         } else {
 161             memset(data + 1, 0, nwords * uint.sizeof);
 162         }
 163     }
 164
 165     void copy(GCBits *f)
 166     in
 167     {
 168         assert(nwords == f.nwords);
 169     }
 170     body
 171     {
 172         version(MEMCPY_NON_SIG_SAFE) {
 173             uint * d1=data+1,d2=f.data+1,dEnd=d1+nwords;
 174             for (;d1!=dEnd;++d1,++d2)
 175                 *d1=*d2;
 176         } else {
 177             memcpy(data + 1, f.data + 1, nwords * uint.sizeof);
 178         }
 179     }
 180
 181     uint* base()
 182     in
 183     {
 184         assert(data);
 185     }
 186     body
 187     {
 188         return data + 1;
 189     }
 190 }
 191
 192 unittest
 193 {
 194     GCBits b;
 195
 196     b.alloc(786);
 197     assert(b.test(123) == 0);
 198     assert(b.testClear(123) == 0);
 199     b.set(123);
 200     assert(b.test(123) != 0);
 201     assert(b.testClear(123) != 0);
 202     assert(b.test(123) == 0);
 203
 204     b.set(785);
 205     b.set(0);
 206     assert(b.test(785) != 0);
 207     assert(b.test(0) != 0);
 208     b.zero();
 209     assert(b.test(785) == 0);
 210     assert(b.test(0) == 0);
 211
 212     GCBits b2;
 213     b2.alloc(786);
 214     b2.set(38);
 215     b.copy(&b2);
 216     assert(b.test(38) != 0);
 217     b2.Dtor();
 218
 219     b.Dtor();
 220 }