micro/plot-c.gpi

   1 #!/usr/bin/gnuplot
   2
   3 # Terminal
   4 set term postscript eps monochrome size 10,7 "Helvetica" 20
   5 set output "@@OUT@@"
   6
   7 # Labels
   8 set multiplot title "Collections for @@PRG@@ (@@COL@@ collector)"
   9
  10 # Tics
  11 set xtics offset 0,graph 1.07
  12 #set xtics textcolor rgb 'white'
  13 set mxtics
  14 set ytics mirror
  15 set mytics
  16 set autoscale xfixmax
  17 set grid xtics ytics mxtics
  18
  19 # Style
  20 set style fill solid noborder
  21
  22 # Upper plot (space)
  23 set lmargin at screen 0.10
  24 set rmargin at screen 0.98
  25 set bmargin at screen 0.40
  26 set tmargin at screen 0.88
  27
  28 # Reference
  29 set key reverse Left center at screen 0.5,0.92 horizontal
  30
  31 # Labels
  32 set ylabel "Space (KiB)"
  33 set label 1 "After collection" at graph 0.02,0.03 left
  34 set label 2 "Before collection" at graph 0.02,0.97 left
  35
  36 # Macros
  37 set macros
  38 black = "lc rgb 'black'"
  39 dgray = "lc rgb 'gray40'"
  40 lgray = "lc rgb 'gray70'"
  41 white = "lc rgb 'gray90'"
  42
  43 # Plot
  44 set datafile separator ','
  45 plot '@@IN@@' \
  46            using 1:(($5+$6+$7+$8)/1024) title 'Overhead' with boxes @black, \
  47         '' using 1:(($5+$6+$7)/1024)    title 'Wasted'   with boxes @lgray, \
  48         '' using 1:(($5+$6)/1024)       title 'Free'     with boxes @dgray, \
  49         '' using 1:($5/1024)            title 'Used'     with boxes @white, \
  50         '' using 1:((-$9-$10-$11-$12)/1024) notitle      with boxes @black, \
  51         '' using 1:((-$9-$10-$11)/1024)     notitle      with boxes @lgray, \
  52         '' using 1:((-$9-$10)/1024)         notitle      with boxes @dgray, \
  53         '' using 1:(-$9/1024)               notitle      with boxes @white, \
  54         0 notitle with lines @black
  55
  56
  57
  58 # Lower plot 2 (space)
  59 set bmargin at screen 0.10
  60 set tmargin at screen 0.40
  61
  62 # Reference
  63 set key reverse Left center bmargin horizontal
  64
  65 # Labels
  66 set ylabel "Time (seconds)"
  67 set xlabel "Program run time (seconds)"
  68 unset label 1
  69 unset label 2
  70
  71 # Tics
  72 unset xtics
  73 set xtics
  74
  75 # Macros
  76 set macros
  77 black = "lc rgb 'black'"
  78 gray  = "lc rgb 'gray40'"
  79 white = "lc rgb 'gray80'"
  80
  81 # Plot
  82 set datafile separator ','
  83 plot '@@IN@@' \
  84            using 1:2 title 'Malloc'        with boxes @black, \
  85         '' using 1:3 title 'Collect'       with boxes @gray, \
  86         '' using 1:4 title 'Stop the word' with boxes @white
  87