configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.54])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER([config.h])
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11 AM_INIT_AUTOMAKE(mutt, $mutt_cv_version)
  12 AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/VERSION'])
  13
  14 AC_GNU_SOURCE
  15
  16 ALL_LINGUAS="de eu ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg ga"
  17
  18 AC_CANONICAL_HOST
  19
  20 AC_MSG_CHECKING([for prefix])
  21 if test x$prefix = xNONE; then
  22   mutt_cv_prefix=$ac_default_prefix
  23 else
  24   mutt_cv_prefix=$prefix
  25 fi
  26 AC_MSG_RESULT($mutt_cv_prefix)
  27
  28 AC_PROG_CC
  29 AC_ISC_POSIX
  30 AM_C_PROTOTYPES
  31 if test "x$U" != "x"; then
  32   AC_MSG_ERROR(Compiler not ANSI compliant)
  33 fi
  34 AC_PROG_CPP
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(AR, ar, ar)
  39
  40 AC_C_INLINE
  41 AC_C_CONST
  42 AC_C_BIGENDIAN
  43
  44 AC_SYS_LARGEFILE
  45 AC_FUNC_FSEEKO
  46 AC_CHECK_SIZEOF(off_t)
  47
  48 AC_PATH_PROG(DBX, dbx, no)
  49 AC_PATH_PROG(GDB, gdb, no)
  50 AC_PATH_PROG(SDB, sdb, no)
  51
  52 if test $GDB != no ; then
  53         DEBUGGER=$GDB
  54 elif test $DBX != no ; then
  55         DEBUGGER=$DBX
  56 elif test $SDB != no ; then
  57         DEBUGGER=$SDB
  58 else
  59         DEBUGGER=no
  60 fi
  61
  62 AC_SUBST([DEBUGGER])
  63
  64 AH_TEMPLATE([sig_atomic_t],
  65             [/* Define to `int' if <signal.h> doesn't define.])
  66 AH_TEMPLATE([HAVE_START_COLOR],
  67             [Define if you have start_color, as a function or macro.])
  68 AH_TEMPLATE([HAVE_TYPEAHEAD],
  69             [Define if you have typeahead, as a function or macro.])
  70 AH_TEMPLATE([HAVE_BKGDSET],
  71             [Define if you have bkgdset, as a function or macro.])
  72 AH_TEMPLATE([HAVE_CURS_SET],
  73             [Define if you have curs_set, as a function or macro.])
  74 AH_TEMPLATE([HAVE_META],
  75             [Define if you have meta, as a function or macro.])
  76 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  77             [Define if you have use_default_colors, as a function or macro.])
  78 AH_TEMPLATE([HAVE_RESIZETERM],
  79             [Define if you have resizeterm, as a function or macro.])
  80 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  81             [Some systems declare sig_atomic_t as volatile, some others -- no.
  82              This define will have value `sig_atomic_t' or
  83              `volatile sig_atomic_t' accordingly.])
  84 AH_TEMPLATE([ICONV_NONTRANS],
  85             [Define as 1 if iconv() only converts exactly and we should treat
  86              all return values other than (size_t)(-1) as equivalent.])
  87
  88 AH_BOTTOM([/* fseeko portability defines */
  89 #ifdef HAVE_FSEEKO
  90 # define LOFF_T off_t
  91 # if HAVE_C99_INTTYPES && HAVE_INTTYPES_H
  92 #  if SIZEOF_OFF_T == 8
  93 #   define OFF_T_FMT "%" PRId64
  94 #  else
  95 #   define OFF_T_FMT "%" PRId32
  96 #  endif
  97 # else
  98 #  if (SIZEOF_OFF_T == 8) && (SIZEOF_LONG == 4)
  99 #   define OFF_T_FMT "%lld"
 100 #  else
 101 #   define OFF_T_FMT "%ld"
 102 #  endif
 103 # endif
 104 #else
 105 # define LOFF_T long
 106 # define fseeko fseek
 107 # define ftello ftell
 108 # define OFF_T_FMT "%ld"
 109 #endif
 110 ])
 111 MUTT_C99_INTTYPES
 112
 113 ac_aux_path_sendmail=/usr/sbin:/usr/lib
 114 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
 115 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL", [Where to find sendmail on your system.])
 116
 117 OPS='$(srcdir)/OPS'
 118
 119 AC_MSG_CHECKING([whether to build with GPGME support])
 120 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 121 [       if test x$enableval = xyes; then
 122                 enable_gpgme=yes
 123         fi
 124 ])
 125
 126 if test x"$enable_gpgme" = xyes; then
 127    AC_MSG_RESULT(yes)
 128    AM_PATH_GPGME(1.0.0, AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 129                  [Defined, if GPGME support is enabled]),
 130                  [gpgme_found=no])
 131    if test x"$gpgme_found" = xno; then
 132       AC_MSG_ERROR([*** GPGME not found ***])
 133    else
 134       AM_PATH_GPGME(1.1.1, AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
 135                                   [Define if GPGME supports PKA]))
 136       #needed to get GPGME_LIBS and al correctly
 137       AM_PATH_GPGME(1.0.0, AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 138                     [Define if you use GPGME to support OpenPGP]))
 139       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 140    fi
 141 else
 142    AC_MSG_RESULT([no])
 143 fi
 144
 145 AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 146 [       if test x$enableval = xno ; then
 147                 have_pgp=no
 148         fi
 149 ])
 150
 151 if test x$have_pgp != xno ; then
 152         AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1, [Define if you want classic PGP support.])
 153         PGPAUX_TARGET="pgpring\$(EXEEXT) pgpewrap\$(EXEEXT)"
 154         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 155 fi
 156
 157 AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 158 [       if test x$enableval = xno ; then
 159                 have_smime=no
 160         fi
 161 ])
 162
 163 if test x$have_smime != xno ; then
 164         AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME, 1, [Define if you want clasic S/MIME support.])
 165         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 166         SMIMEAUX_TARGET="smime_keys"
 167 fi
 168
 169 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster@<:@=PATH@:>@], [Include Mixmaster support]),
 170   [if test "$withval" != no
 171    then
 172      if test -x "$withval"
 173      then
 174        MIXMASTER="$withval"
 175      else
 176        MIXMASTER="mixmaster"
 177      fi
 178      OPS="$OPS \$(srcdir)/OPS.MIX"
 179      MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 180      AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [Where to find mixmaster on your system.])
 181    fi])
 182
 183 # We now require all OPS
 184 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 185 AC_SUBST([OPS])
 186
 187 AC_SUBST(PGPAUX_TARGET)
 188 AC_SUBST(SMIMEAUX_TARGET)
 189
 190 AC_PATH_PROG(ISPELL, ispell, no)
 191 if test $ISPELL != no; then
 192         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 193 fi
 194
 195 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang@<:@=DIR@:>@], [Use S-Lang instead of ncurses]),
 196         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 197                 [AC_TRY_RUN([#include <sys/param.h>
 198 #include <stdlib.h>
 199
 200 main ()
 201 {
 202 #ifdef BSD
 203         exit (0);
 204 #else
 205         exit (1);
 206 #endif
 207 }],
 208                         mutt_cv_bsdish=yes,
 209                         mutt_cv_bsdish=no,
 210                         mutt_cv_bsdish=no)])
 211
 212         AC_MSG_CHECKING(for S-Lang)
 213         if test $withval = yes; then
 214                 if test -d $srcdir/../slang; then
 215                         mutt_cv_slang=$srcdir/../slang/src
 216                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 217                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 218                 else
 219                         if test -d $mutt_cv_prefix/include/slang; then
 220                                 CPPFLAGS="$CPPFLAGS -I$mutt_cv_prefix/include/slang"
 221                         elif test -d /usr/include/slang; then
 222                                 CPPFLAGS="$CPPFLAGS -I/usr/include/slang"
 223                         fi
 224                         mutt_cv_slang=yes
 225                 fi
 226         else
 227                 dnl ---Check to see if $withval is a source directory
 228                 if test -f $withval/src/slang.h; then
 229                         mutt_cv_slang=$withval/src
 230                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 231                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 232                 else
 233                         dnl ---Must be installed somewhere
 234                         mutt_cv_slang=$withval
 235                         if test -d $withval/include/slang; then
 236                                 CPPFLAGS="$CPPFLAGS -I${withval}/include/slang"
 237                         elif test -d $withval/include; then
 238                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 239                         fi
 240                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 241                 fi
 242         fi
 243         AC_MSG_RESULT($mutt_cv_slang)
 244         if test $mutt_cv_bsdish = yes; then
 245                 AC_CHECK_LIB(termlib, main)
 246         fi
 247         AC_DEFINE(USE_SLANG_CURSES,1,
 248                 [ Define if you compile with SLang instead of curses/ncurses. ])
 249         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 250         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 251
 252         dnl --- now that we've found it, check the link
 253
 254         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 255                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 256                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 257
 258         ],
 259
 260         [mutt_cv_curses=/usr
 261         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 262                 [if test $withval != yes; then
 263                         mutt_cv_curses=$withval
 264                 fi
 265                 if test x$mutt_cv_curses != x/usr; then
 266                         LDFLAGS="$LDFLAGS -L${mutt_cv_curses}/lib"
 267                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 268                 fi])
 269
 270         AC_CHECK_FUNC(initscr,,[
 271         cf_ncurses="ncurses"
 272         for lib in ncurses ncursesw
 273         do
 274                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 275         done
 276         AC_CHECK_LIB($cf_ncurses, initscr,
 277                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 278
 279                 if test "$cf_ncurses" = ncursesw; then
 280                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 281                 else
 282                   AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"],
 283                     [AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])])
 284                 fi],
 285
 286                 [CF_CURSES_LIBS])
 287                 ])
 288
 289         old_LIBS="$LIBS"
 290         LIBS="$LIBS $MUTTLIBS"
 291         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 292                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 293         if test "$ac_cv_func_decl_start_color" = yes; then
 294                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 295         fi
 296         if test "$ac_cv_func_decl_resizeterm" = yes; then
 297                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 298         fi
 299         LIBS="$old_LIBS"
 300         ])
 301
 302 AC_HEADER_STDC
 303
 304 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 305 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 306 AC_CHECK_HEADERS(unix.h)
 307
 308 AC_CHECK_FUNCS(setrlimit getsid)
 309
 310 AC_TYPE_SIGNAL
 311
 312 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 313 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 314   [
 315     ac_cv_type_sig_atomic_t=yes;
 316     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 317                     signal.h,
 318                     [
 319                         is_sig_atomic_t_volatile=yes;
 320                         AC_MSG_RESULT([yes, volatile])
 321                     ],
 322                     [
 323                         is_sig_atomic_t_volatile=no;
 324                         AC_MSG_RESULT([yes, non volatile])
 325                     ])
 326   ],
 327   [
 328     AC_MSG_RESULT(no)
 329     AC_CHECK_TYPE(sig_atomic_t, int)
 330     is_sig_atomic_t_volatile=no
 331   ])
 332 if test $is_sig_atomic_t_volatile = 'yes'
 333 then
 334     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 335 else
 336     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 337 fi
 338
 339 AC_DECL_SYS_SIGLIST
 340
 341 AC_TYPE_PID_T
 342 AC_CHECK_TYPE(ssize_t, int)
 343
 344 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 345
 346 AC_REPLACE_FUNCS([setenv strcasecmp strdup strsep strtok_r wcscasecmp])
 347 AC_REPLACE_FUNCS([strcasestr mkdtemp])
 348
 349 AC_CHECK_FUNC(getopt)
 350 if test $ac_cv_func_getopt = yes; then
 351         AC_CHECK_HEADERS(getopt.h)
 352 fi
 353
 354 SNPRINTFOBJS=""
 355 AC_CHECK_FUNC(snprintf, [mutt_cv_func_snprintf=yes], [mutt_cv_func_snprintf=no])
 356 AC_CHECK_FUNC(vsnprintf, [mutt_cv_func_vsnprintf=yes], [mutt_cv_func_vsnprintf=no])
 357 if test $mutt_cv_func_snprintf = yes; then
 358 AC_CACHE_CHECK([whether your system's snprintf is C99 compliant],
 359         [mutt_cv_c99_snprintf],
 360         AC_TRY_RUN([
 361 #include <stdio.h>
 362 int main()
 363 {
 364 changequote(, )dnl
 365   char buf[8];
 366   int len = snprintf(buf, 4, "1234567");
 367   return (len != 7 || buf[3] != '\0');
 368 changequote([, ])dnl
 369 }
 370         ], mutt_cv_c99_snprintf=yes, mutt_cv_c99_snprintf=no, mutt_cv_c99_snprintf=no))
 371 else
 372         mutt_cv_c99_snprintf=no
 373 fi
 374 if test $mutt_cv_func_vsnprintf = yes; then
 375 AC_CACHE_CHECK([whether your system's vsnprintf is C99 compliant],
 376         [mutt_cv_c99_vsnprintf],
 377         AC_TRY_RUN([
 378 #include <stdarg.h>
 379 #include <stdio.h>
 380 int foo(const char *fmt, ...)
 381 {
 382 changequote(, )dnl
 383   char buf[8];
 384   int len;
 385   va_list ap;
 386   va_start(ap, fmt);
 387   len = vsnprintf(buf, 4, fmt, ap);
 388   va_end(ap);
 389   return (len != 7 || buf[3] != '\0');
 390 changequote([, ])dnl
 391 }
 392
 393 int main()
 394 {
 395   return foo("%s", "1234567");
 396 }
 397         ], mutt_cv_c99_vsnprintf=yes, mutt_cv_c99_vsnprintf=no, mutt_cv_c99_vsnprintf=no))
 398 else
 399         mutt_cv_c99_vsnprintf=no
 400 fi
 401 if test $mutt_cv_c99_snprintf = yes; then
 402         AC_DEFINE(HAVE_SNPRINTF, 1, [ Define to 1 if you have a C99 compliant snprintf function. ])
 403 fi
 404 if test $mutt_cv_c99_vsnprintf = yes; then
 405         AC_DEFINE(HAVE_VSNPRINTF, 1, [ Define to 1 if you have a C99 compliant vsnprintf function. ])
 406 fi
 407 if test $mutt_cv_c99_snprintf = no -o $mutt_cv_c99_vsnprintf = no; then
 408         AC_LIBOBJ(snprintf)
 409 fi
 410
 411 XIPH_FUNC_VA_COPY
 412
 413 dnl SCO uses chsize() instead of ftruncate()
 414 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 415
 416 dnl SCO has strftime() in libintl
 417 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 418
 419 dnl AIX may not have fchdir()
 420 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 421
 422 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 423         [mutt_cv_regex=yes],
 424         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 425
 426 if test $mutt_cv_regex = no ; then
 427 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 428         [mutt_cv_regex_broken],
 429         AC_TRY_RUN([
 430 #include <unistd.h>
 431 #include <regex.h>
 432 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 433         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 434         if test $mutt_cv_regex_broken = yes ; then
 435                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 436                 mutt_cv_regex=yes
 437         fi
 438 fi
 439
 440 if test $mutt_cv_regex = yes; then
 441         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 442         AC_LIBOBJ(regex)
 443 fi
 444
 445
 446 AC_ARG_WITH(homespool,
 447   AC_HELP_STRING([--with-homespool@<:@=FILE@:>@], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 448 if test x$with_homespool != x; then
 449         if test $with_homespool = yes; then
 450                 with_homespool=mailbox
 451         fi
 452         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 453         AC_DEFINE(HOMESPOOL,1,
 454           [Is mail spooled to the user's home directory?  If defined,
 455            MAILPATH should be set to the filename of the spool mailbox
 456            relative the the home directory.
 457            use: configure --with-homespool=FILE])
 458         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 459         mutt_cv_setgid=no
 460 else
 461         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 462                 [mutt_cv_mailpath=$withval],
 463                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 464                         [mutt_cv_mailpath=no
 465                         if test -d /var/mail; then
 466                                 mutt_cv_mailpath=/var/mail
 467                         elif test -d /var/spool/mail; then
 468                                 mutt_cv_mailpath=/var/spool/mail
 469                         elif test -d /usr/spool/mail; then
 470                                 mutt_cv_mailpath=/usr/spool/mail
 471                         elif test -d /usr/mail; then
 472                                 mutt_cv_mailpath=/usr/mail
 473                         fi])
 474                 ])
 475         if test "$mutt_cv_mailpath" = no; then
 476                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 477         fi
 478         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 479
 480         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 481 #include <sys/stat.h>
 482 #include <stdlib.h>
 483
 484 int main (int argc, char **argv)
 485 {
 486         struct stat s;
 487
 488         stat ("$mutt_cv_mailpath", &s);
 489         if (s.st_mode & S_IWOTH) exit (0);
 490         exit (1);
 491 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 492
 493         mutt_cv_setgid=no
 494         if test $mutt_cv_worldwrite = yes; then
 495                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 496         else
 497
 498                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 499 #include <sys/stat.h>
 500 #include <stdlib.h>
 501
 502 int main (int argc, char **argv)
 503 {
 504         struct stat s;
 505
 506         stat ("$mutt_cv_mailpath", &s);
 507         if (s.st_mode & S_IWGRP) exit (0);
 508         exit (1);
 509 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 510
 511                 if test $mutt_cv_groupwrite = yes; then
 512                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 513                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 514                         mutt_cv_setgid=yes
 515                 fi
 516         fi
 517 fi
 518
 519 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 520         [mutt_cv_external_dotlock="$enableval"])
 521
 522 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 523         || test "x$mutt_cv_external_dotlock" = "xyes"
 524 then
 525         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 526         DOTLOCK_TARGET="mutt_dotlock\$(EXEEXT)"
 527 else
 528         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 529 fi
 530
 531 AC_SUBST(DOTLOCK_TARGET)
 532
 533 dnl autoconf <2.60 compatibility
 534 if test -z "$datarootdir"; then
 535   datarootdir='${prefix}/share'
 536 fi
 537 AC_SUBST([datarootdir])
 538
 539 AC_MSG_CHECKING(where to put the documentation)
 540 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 541         [mutt_cv_docdir=$withval],
 542         [mutt_cv_docdir='${datarootdir}/doc/mutt'])
 543 AC_MSG_RESULT($mutt_cv_docdir)
 544
 545 docdir=$mutt_cv_docdir
 546 AC_SUBST(docdir)
 547
 548 if test x$mutt_cv_setgid = xyes; then
 549         DOTLOCK_GROUP='mail'
 550         DOTLOCK_PERMISSION=2755
 551 else
 552         DOTLOCK_GROUP=''
 553         DOTLOCK_PERMISSION=755
 554 fi
 555 AC_SUBST(DOTLOCK_GROUP)
 556 AC_SUBST(DOTLOCK_PERMISSION)
 557
 558 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 559         [if test $withval != yes; then
 560             if test $withval != no; then
 561                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 562             fi
 563         fi])
 564
 565 need_socket="no"
 566
 567 dnl -- socket dependencies --
 568
 569 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 570 [       if test x$enableval = xyes ; then
 571                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 572                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pop.o pop_lib.o pop_auth.o"
 573                 need_pop="yes"
 574                 need_socket="yes"
 575                 need_md5="yes"
 576         fi
 577 ])
 578
 579 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 580 [       if test x$enableval = xyes ; then
 581                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 582                 LIBIMAP="-Limap -limap"
 583                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 584                 need_imap="yes"
 585                 need_socket="yes"
 586                 need_md5="yes"
 587         fi
 588 ])
 589 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 590
 591 AC_ARG_ENABLE(smtp, AC_HELP_STRING([--enable-smtp], [include internal SMTP relay support]),
 592         [if test $enableval = yes; then
 593                 AC_DEFINE(USE_SMTP, 1, [Include internal SMTP relay support])
 594                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smtp.o"
 595                 need_socket="yes"
 596         fi])
 597
 598 if test x"$need_imap" = xyes -o x"$need_pop" = xyes ; then
 599   MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS bcache.o"
 600 fi
 601
 602 dnl -- end socket dependencies --
 603
 604 if test "$need_socket" = "yes"
 605 then
 606         AC_CHECK_HEADERS([sys/select.h])
 607         AC_MSG_CHECKING([for socklen_t])
 608         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 609                 AC_MSG_RESULT([no])
 610                 AC_DEFINE(socklen_t,int,
 611                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 612         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 613         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 614         AC_CHECK_FUNCS(getaddrinfo)
 615         AC_DEFINE(USE_SOCKET,1,
 616                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 617         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 618 fi
 619
 620 dnl -- imap dependencies --
 621
 622 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss@<:@=PFX@:>@], [Compile in GSSAPI authentication for IMAP]),
 623     gss_prefix="$withval", gss_prefix="no")
 624 if test "$gss_prefix" != "no"
 625 then
 626   if test "$need_imap" = "yes"
 627   then
 628     MUTT_AM_PATH_GSSAPI(gss_prefix)
 629     AC_MSG_CHECKING(GSSAPI implementation)
 630     AC_MSG_RESULT($GSSAPI_IMPL)
 631     if test "$GSSAPI_IMPL" = "none"
 632     then
 633       AC_CACHE_SAVE
 634       AC_MSG_RESULT([GSSAPI libraries not found])
 635     fi
 636     if test "$GSSAPI_IMPL" = "Heimdal"
 637     then
 638       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 639     fi
 640     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 641     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 642     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 643     need_gss="yes"
 644   else
 645     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 646   fi
 647 fi
 648 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 649
 650 dnl -- end imap dependencies --
 651
 652 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl@<:@=PFX@:>@], [Enable TLS support using OpenSSL]),
 653 [       if test "$with_ssl" != "no"
 654         then
 655           if test "$need_socket" != "yes"; then
 656            AC_MSG_WARN([SSL support is only useful with POP, IMAP or SMTP support])
 657           else
 658             if test "$with_ssl" != "yes"
 659             then
 660              LDFLAGS="$LDFLAGS -L$withval/lib"
 661              CPPFLAGS="$CPPFLAGS -I$withval/include"
 662             fi
 663             saved_LIBS="$LIBS"
 664
 665             crypto_libs=""
 666             AC_CHECK_LIB(z, deflate, [crypto_libs=-lz])
 667             AC_CHECK_LIB(crypto, X509_new,
 668               [crypto_libs="-lcrypto $crypto_libs"],, [$crypto_libs])
 669             AC_CHECK_LIB(ssl, SSL_new,,
 670               AC_MSG_ERROR([Unable to find SSL library]), [$crypto_libs])
 671
 672             LIBS="$LIBS $crypto_libs"
 673             AC_CHECK_FUNCS(RAND_status RAND_egd)
 674
 675             AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 676             AC_DEFINE(USE_SSL_OPENSSL,1,[ Define if you want support for SSL via OpenSSL. ])
 677             LIBS="$saved_LIBS"
 678             MUTTLIBS="$MUTTLIBS -lssl $crypto_libs"
 679             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 680             need_ssl=yes
 681           fi
 682         fi
 683 ])
 684
 685 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls@<:@=PFX@:>@], [enable TLS support using gnutls]),
 686     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 687 if test "$gnutls_prefix" != "no" && test x"$need_ssl" != xyes
 688 then
 689   if test "$need_socket" != "yes"
 690   then
 691     AC_MSG_WARN([SSL support is only useful with POP, IMAP or SMTP support])
 692   else
 693     if test "$gnutls_prefix" != "yes"
 694     then
 695       LDFLAGS="$LDFLAGS -L$gnutls_prefix/lib"
 696       CPPFLAGS="$CPPFLAGS -I$gnutls_prefix/include"
 697     fi
 698     saved_LIBS="$LIBS"
 699
 700     AC_CHECK_LIB(gnutls, gnutls_check_version,
 701       [dnl GNUTLS found
 702       AC_CHECK_DECLS([GNUTLS_VERIFY_DISABLE_TIME_CHECKS], [], [],
 703                     [[#include <gnutls/x509.h>]])
 704
 705       LIBS="$saved_LIBS"
 706       MUTTLIBS="$MUTTLIBS -lgnutls"
 707
 708       AC_DEFINE(USE_SSL, 1, [ Define if you want support for SSL. ])
 709       AC_DEFINE(USE_SSL_GNUTLS, 1, [ Define if you want support for SSL via GNUTLS. ])
 710
 711       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 712       need_ssl=yes],
 713       [AC_MSG_ERROR([could not find libgnutls])])
 714   fi
 715 fi
 716
 717 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 718
 719 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl@<:@=PFX@:>@], [Use Cyrus SASL 2 network security library]),
 720         [
 721         if test "$with_sasl" != "no"
 722         then
 723           if test "$need_socket" != "yes"
 724           then
 725             AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 726           fi
 727
 728           if test "$with_sasl" != "yes"
 729           then
 730             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 731             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 732           fi
 733
 734           saved_LIBS="$LIBS"
 735
 736           AC_CHECK_LIB(sasl2, sasl_client_init,,
 737             AC_MSG_ERROR([could not find libsasl2]),)
 738
 739           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 740           MUTTLIBS="$MUTTLIBS -lsasl2"
 741           LIBS="$saved_LIBS"
 742           AC_DEFINE(USE_SASL,1,
 743                   [ Define if want to use the Cyrus SASL library for POP/IMAP authentication. ])
 744           need_sasl=yes
 745         fi
 746         ])
 747 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 748
 749 dnl -- end socket --
 750
 751 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 752         [ if test x$enableval = xyes ; then
 753                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 754           fi
 755          ])
 756
 757 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 758         [if test $enableval = yes; then
 759                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 760         fi])
 761
 762 mutt_cv_fcntl=yes
 763 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 764         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 765
 766 if test $mutt_cv_fcntl = yes; then
 767         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 768 fi
 769
 770 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 771 ac_cv_dirent_d_ino=no
 772 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 773 if test x$ac_cv_dirent_d_ino = xyes ; then
 774   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 775             [Define to 1 if your system has the dirent::d_ino member])
 776 fi
 777 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 778
 779 mutt_cv_warnings=yes
 780 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 781 [if test $enableval = no; then
 782         mutt_cv_warnings=no
 783 fi])
 784
 785 if test x$GCC = xyes && test $mutt_cv_warnings = yes; then
 786   CFLAGS="-Wall -pedantic -Wno-long-long $CFLAGS"
 787 fi
 788
 789 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 790         [if test x$enableval = xyes; then
 791                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 792                   [Define if you have problems with mutt not detecting
 793                    new/old mailboxes over NFS.  Some NFS implementations
 794                    incorrectly cache the attributes of small files.])
 795         fi])
 796
 797 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support]),
 798         [if test x$enableval = xyes; then
 799                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 800         fi])
 801
 802 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable]),
 803         [if test x$enableval = xyes; then
 804                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 805         fi])
 806
 807 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 808         [if test $withval != yes; then
 809                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 810                  [program to use for shell commands])
 811          else
 812                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 813         fi],
 814         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 815
 816 AC_ARG_ENABLE(exact-address, AC_HELP_STRING([--enable-exact-address], [Enable regeneration of email addresses]),
 817         [if test $enableval = yes; then
 818                 AC_DEFINE(EXACT_ADDRESS,1,
 819                   [Enable exact regeneration of email addresses as parsed?
 820                    NOTE: this requires significant more memory when defined.])
 821
 822         fi])
 823
 824 dnl -- start cache --
 825 db_found=no
 826 db_requested=auto
 827 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache],
 828   [Enable header caching]))
 829 AC_ARG_WITH(tokyocabinet, AC_HELP_STRING([--without-tokyocabinet],
 830   [Don't use tokyocabinet even if it is available]))
 831 AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm],
 832   [Don't use qdbm even if it is available]))
 833 AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm],
 834   [Don't use gdbm even if it is available]))
 835 AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb@<:@=DIR@:>@],
 836   [Use BerkeleyDB4 if gdbm is not available]))
 837
 838 if test x$enable_hcache = xyes
 839 then
 840     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 841     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS hcache.o"
 842
 843     OLDCPPFLAGS="$CPPFLAGS"
 844     OLDLDFLAGS="$LDFLAGS"
 845     OLDLIBS="$LIBS"
 846
 847     need_md5="yes"
 848
 849     if test -n "$with_tokyocabinet" && test "$with_tokyocabinet" != "no"
 850     then
 851       db_requested=tc
 852     fi
 853     if test -n "$with_qdbm" && test "$with_qdbm" != "no"
 854     then
 855       if test "$db_requested" != "auto"
 856       then
 857         AC_MSG_ERROR([more than one header cache engine requested.])
 858       else
 859         db_requested=qdbm
 860       fi
 861     fi
 862     if test -n "$with_gdbm" && test "$with_gdbm" != "no"
 863     then
 864       if test "$db_requested" != "auto"
 865       then
 866         AC_MSG_ERROR([more than one header cache engine requested.])
 867       else
 868         db_requested=gdbm
 869       fi
 870     fi
 871     if test -n "$with_bdb" && test "$with_bdb" != "no"
 872     then
 873       if test "$db_requested" != "auto"
 874       then
 875         AC_MSG_ERROR([more than one header cache engine requested.])
 876       else
 877         db_requested=bdb
 878       fi
 879     fi
 880
 881     dnl -- Tokyo Cabinet --
 882     if test "$with_tokyocabinet" != "no" \
 883             && test "$db_requested" = auto -o "$db_requested" = tc
 884     then
 885       if test -n "$with_tokyocabinet" && test "$with_tokyocabinet" != "yes"
 886       then
 887         CPPFLAGS="$CPPFLAGS -I$with_tokyocabinet/include"
 888         LDFLAGS="$LDFLAGS -L$with_tokyocabinet/lib"
 889       fi
 890
 891       AC_CHECK_HEADER(tcbdb.h,
 892       AC_CHECK_LIB(tokyocabinet, tcbdbopen,
 893         [MUTTLIBS="$MUTTLIBS -ltokyocabinet"
 894          AC_DEFINE(HAVE_TC, 1, [Tokyo Cabinet Support])
 895          db_found=tc],
 896         [CPPFLAGS="$OLDCPPFLAGS"
 897          LDFLAGS="$OLDLDFLAGS"]))
 898       if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 899       then
 900         AC_MSG_ERROR([Tokyo Cabinet could not be used. Check config.log for details.])
 901       fi
 902     fi
 903
 904     dnl -- QDBM --
 905     if test "$with_qdbm" != "no" && test $db_found = no \
 906             && test "$db_requested" = auto -o "$db_requested" = qdbm
 907     then
 908       if test -n "$with_qdbm" && test "$with_qdbm" != "yes"
 909       then
 910         if test -d $with_qdbm/include/qdbm; then
 911           CPPFLAGS="$CPPFLAGS -I$with_qdbm/include/qdbm"
 912         else
 913           CPPFLAGS="$CPPFLAGS -I$with_qdbm/include"
 914         fi
 915         LDFLAGS="$LDFLAGS -L$with_qdbm/lib"
 916       else
 917          if test -d /usr/include/qdbm; then
 918            CPPFLAGS="$CPPFLAGS -I/usr/include/qdbm"
 919          fi
 920       fi
 921
 922       saved_LIBS="$LIBS"
 923       AC_CHECK_HEADERS(villa.h)
 924       AC_CHECK_LIB(qdbm, vlopen,
 925         [MUTTLIBS="$MUTTLIBS -lqdbm"
 926          AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 927          db_found=qdbm],
 928         [CPPFLAGS="$OLDCPPFLAGS"
 929          LDFLAGS="$OLDLDFLAGS"])
 930       LIBS="$saved_LIBS"
 931       if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 932       then
 933         AC_MSG_ERROR([QDBM could not be used. Check config.log for details.])
 934       fi
 935     fi
 936
 937     dnl -- GDBM --
 938     if test x$with_gdbm != xno && test $db_found = no \
 939             && test "$db_requested" = auto -o "$db_requested" = gdbm
 940     then
 941         if test "$with_gdbm" != "yes"
 942         then
 943           CPPFLAGS="$CPPFLAGS -I$with_gdbm/include"
 944           LDFLAGS="$LDFLAGS -L$with_gdbm/lib"
 945         fi
 946         saved_LIBS="$LIBS"
 947         LIBS="$LIBS -lgdbm"
 948         AC_CACHE_CHECK(for gdbm_open, ac_cv_gdbmopen,[
 949             ac_cv_gdbmopen=no
 950             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 951         ])
 952         LIBS="$saved_LIBS"
 953         if test "$ac_cv_gdbmopen" = yes
 954         then
 955           AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 956           MUTTLIBS="$MUTTLIBS -lgdbm"
 957           db_found=gdbm
 958         fi
 959         if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 960         then
 961           AC_MSG_ERROR([GDBM could not be used. Check config.log for details.])
 962         fi
 963     fi
 964
 965     dnl -- BDB --
 966     ac_bdb_prefix="$with_bdb"
 967     if test x$ac_bdb_prefix != xno && test $db_found = no
 968     then
 969         if test x$ac_bdb_prefix = xyes || test x$ac_bdb_prefix = x
 970         then
 971           ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 972         fi
 973         for d in $ac_bdb_prefix; do
 974             bdbpfx="$bdbpfx $d"
 975             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 976                 bdbpfx="$bdbpfx $d/$v"
 977             done
 978         done
 979         BDB_VERSIONS="db-4 db4 db-4.6 db4.6 db46 db-4.5 db4.5 db45 db-4.4 db4.4 db44 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 980         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 981         for d in $bdbpfx; do
 982             BDB_INCLUDE_DIR=""
 983             BDB_LIB_DIR=""
 984             for v in / $BDB_VERSIONS; do
 985                 if test -r "$d/include/$v/db.h"; then
 986                     BDB_INCLUDE_DIR="$d/include/$v"
 987                     for bdblibdir in "$d/lib/$v" "$d/lib"; do
 988                         test -d "$bdblibdir" || continue
 989                         BDB_LIB_DIR="$bdblibdir"
 990                         for l in `echo $BDB_VERSIONS`; do
 991                             CPPFLAGS="$OLDCPPFLAGS -I$BDB_INCLUDE_DIR"
 992                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
 993                             AC_TRY_LINK([
 994                                 #include <stdlib.h>
 995                                 #include <db.h>
 996                             ],[
 997                                 DB *db = NULL;
 998                                 db->open(db,NULL,NULL,NULL,0,0,0);
 999                             ],[
1000                                 ac_cv_dbcreate=yes
1001                                 BDB_LIB="$l"
1002                                 break
1003                             ])
1004                         done
1005                         test x$ac_cv_dbcreate = xyes && break 2
1006                     done
1007                 fi
1008             done
1009             test x$BDB_LIB != x && break
1010         done
1011         if test x$ac_cv_dbcreate = xyes
1012         then
1013             AC_MSG_RESULT(yes)
1014             CPPFLAGS="$OLDCPPFLAGS -I$BDB_INCLUDE_DIR"
1015             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
1016             AC_DEFINE(HAVE_DB4, 1, [Berkeley DB4 Support])
1017             db_found=bdb
1018         else
1019             AC_MSG_RESULT(no)
1020         fi
1021     fi
1022
1023     if test $db_found = no
1024     then
1025         AC_MSG_ERROR([You need Tokyo Cabinet, QDBM, GDBM or Berkeley DB4 for hcache])
1026     fi
1027 fi
1028 dnl -- end cache --
1029
1030 if test "$need_md5" = "yes"
1031 then
1032   MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS md5.o"
1033   MUTT_MD5="mutt_md5"
1034 fi
1035 AC_SUBST(MUTT_MD5)
1036
1037 AC_SUBST(MUTTLIBS)
1038 AC_SUBST(MUTT_LIB_OBJECTS)
1039 AC_SUBST(LIBIMAP)
1040 AC_SUBST(LIBIMAPDEPS)
1041
1042 dnl -- iconv/gettext --
1043
1044 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
1045         [if test x$enableval = xno ; then
1046                 am_cv_func_iconv=no
1047         fi
1048 ])
1049
1050 MUTT_AM_GNU_GETTEXT
1051
1052 if test "$am_cv_func_iconv" != "yes"
1053 then
1054   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
1055 else
1056
1057 AC_CHECK_HEADERS(iconv.h,
1058         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
1059          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
1060                 [AC_MSG_RESULT(yes)
1061                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
1062                         [Define if <iconv.h> defines iconv_t.])],
1063                  AC_MSG_RESULT(no))])
1064
1065 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
1066 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
1067 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
1068 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
1069         mutt_save_LIBS="$LIBS"
1070         LIBS="$LIBS $LIBICONV"
1071         AC_TRY_RUN([
1072 #include <iconv.h>
1073 int main()
1074 {
1075   iconv_t cd;
1076 changequote(, )dnl
1077   char buf[4];
1078 changequote([, ])dnl
1079   char *ob;
1080   size_t obl;
1081   ob = buf, obl = sizeof(buf);
1082   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
1083           (iconv(cd, 0, 0, &ob, &obl) ||
1084            !(ob == buf && obl == sizeof(buf)) ||
1085            iconv_close(cd)));
1086 }
1087                 ],
1088                 mutt_cv_iconv_good=yes,
1089                 mutt_cv_iconv_good=no,
1090                 mutt_cv_iconv_good=yes)
1091         LIBS="$mutt_save_LIBS")
1092 if test "$mutt_cv_iconv_good" = no; then
1093   AC_MSG_ERROR(Try using libiconv instead)
1094 fi
1095
1096 dnl This is to detect implementations such as the one in glibc-2.1,
1097 dnl which always convert exactly but return the number of characters
1098 dnl converted instead of the number converted inexactly.
1099 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
1100         mutt_save_LIBS="$LIBS"
1101         LIBS="$LIBS $LIBICONV"
1102         AC_TRY_RUN([
1103 #include <iconv.h>
1104 #include <string.h>
1105 int main()
1106 {
1107   iconv_t cd;
1108   const char *ib;
1109   char *ob;
1110   size_t ibl, obl;
1111   const char *s = "\304\211";
1112 changequote(, )dnl
1113   char t[3];
1114 changequote([, ])dnl
1115   ib = s, ibl = 2, ob = t, obl = 3;
1116   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1117           iconv(cd, &ib, &ibl, &ob, &obl));
1118 }
1119                 ],
1120                 mutt_cv_iconv_nontrans=no,
1121                 mutt_cv_iconv_nontrans=yes,
1122                 mutt_cv_iconv_nontrans=no)
1123         LIBS="$mutt_save_LIBS")
1124 if test "$mutt_cv_iconv_nontrans" = yes; then
1125   AC_DEFINE(ICONV_NONTRANS, 1)
1126 else
1127   AC_DEFINE(ICONV_NONTRANS, 0)
1128 fi
1129
1130 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1131
1132 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1133   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1134           [ Define if your gettext has bind_textdomain_codeset. ])
1135 else
1136   mutt_save_LIBS="$LIBS"
1137   LIBS="$LIBS $INTLLIBS"
1138   AC_CHECK_FUNCS(bind_textdomain_codeset)
1139   LIBS="$mutt_save_LIBS"
1140 fi
1141
1142 fi # libiconv
1143
1144 dnl -- IDN depends on iconv
1145
1146 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=@<:@PFX@:>@], [Use GNU libidn for domain names]),
1147                  [
1148                   if test "$with_idn" != "no" ; then
1149                         if test "$with_idn" != "yes" ; then
1150                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
1151                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
1152                         fi
1153                   fi
1154                  ]
1155 )
1156
1157 if test "x$with_idn" != "xno"; then
1158   if test "$am_cv_func_iconv" != "yes"
1159   then
1160     if test "x$with_idn" != "x"
1161     then
1162       AC_MSG_ERROR([IDN requested but iconv is disabled or unavailable])
1163     fi
1164   else
1165     AC_SEARCH_LIBS([stringprep_check_version], [idn], [
1166       AC_DEFINE([HAVE_LIBIDN], 1, [Define to 1 if you have the `idn' library])
1167       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_idna.o"
1168     ])
1169     AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
1170     AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
1171     AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
1172   fi
1173 fi
1174
1175 dnl -- locales --
1176
1177 AC_CHECK_HEADERS(wchar.h)
1178
1179 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1180         AC_TRY_COMPILE([
1181 #include <stddef.h>
1182 #include <stdlib.h>
1183 #ifdef HAVE_WCHAR_H
1184 #include <wchar.h>
1185 #endif
1186                 ],
1187                 [ wchar_t wc; return 0; ],
1188                 mutt_cv_wchar_t=yes,
1189                 mutt_cv_wchar_t=no))
1190
1191 if test "$mutt_cv_wchar_t" = no; then
1192         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1193 fi
1194
1195 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1196         AC_TRY_COMPILE([
1197 #include <stddef.h>
1198 #include <stdlib.h>
1199 #ifdef HAVE_WCHAR_H
1200 #include <wchar.h>
1201 #endif
1202                 ],
1203                 [ wint_t wc; return 0; ],
1204                 mutt_cv_wint_t=yes,
1205                 mutt_cv_wint_t=no))
1206
1207 if test "$mutt_cv_wint_t" = no; then
1208         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1209 fi
1210
1211 AC_CHECK_HEADERS(wctype.h)
1212 AC_CHECK_FUNCS(iswalnum iswalpha  iswcntrl iswdigit)
1213 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1214 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1215
1216 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1217         AC_TRY_COMPILE([
1218 #include <stddef.h>
1219 #include <stdlib.h>
1220 #ifdef HAVE_WCHAR_H
1221 #include <wchar.h>
1222 #endif
1223                 ],
1224                 [ mbstate_t s; return 0; ],
1225                 mutt_cv_mbstate_t=yes,
1226                 mutt_cv_mbstate_t=no))
1227
1228 if test "$mutt_cv_mbstate_t" = no; then
1229         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1230 fi
1231
1232 wc_funcs=maybe
1233 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1234         wc_funcs=$withval)
1235
1236 if test "$wc_funcs" != yes && test "$wc_funcs" != no; then
1237         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1238                 mutt_cv_wc_funcs=no
1239                 AC_TRY_LINK([
1240 #define _XOPEN_SOURCE 1
1241 #include <stddef.h>
1242 #include <stdlib.h>
1243 #ifdef HAVE_WCTYPE_H
1244 #include <wctype.h>
1245 #endif
1246 #ifdef HAVE_WCHAR_H
1247 #include <wchar.h>
1248 #endif],
1249                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1250         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1251                         mutt_cv_wc_funcs=yes))
1252         wc_funcs=$mutt_cv_wc_funcs
1253 fi
1254
1255 if test $wc_funcs = yes; then
1256         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1257 else
1258         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS utf8.o wcwidth.o"
1259 fi
1260
1261 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1262   [AC_TRY_LINK([#include <langinfo.h>],
1263     [char* cs = nl_langinfo(CODESET);],
1264     mutt_cv_langinfo_codeset=yes,
1265     mutt_cv_langinfo_codeset=no)])
1266 if test $mutt_cv_langinfo_codeset = yes; then
1267   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1268 fi
1269
1270 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1271   [AC_TRY_LINK([#include <langinfo.h>],
1272     [char* cs = nl_langinfo(YESEXPR);],
1273     mutt_cv_langinfo_yesexpr=yes,
1274     mutt_cv_langinfo_yesexpr=no)])
1275 if test $mutt_cv_langinfo_yesexpr = yes; then
1276   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1277 fi
1278
1279 dnl Documentation tools
1280 have_openjade="no"
1281 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1282 if test "$OSPCAT" != "none"
1283 then
1284   AC_MSG_CHECKING([for openjade docbook stylesheets])
1285   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1286   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1287   # ospcat may spit out an absolute path without an SOIBASE
1288   if test -z "$DSLROOT"
1289   then
1290     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1291   fi
1292   if test -f $DSLROOT/print/docbook.dsl
1293   then
1294     AC_MSG_RESULT([in $DSLROOT])
1295     have_openjade="yes"
1296   else
1297     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1298   fi
1299 fi
1300 AC_SUBST(DSLROOT)
1301
1302 AC_ARG_ENABLE(full_doc,
1303               AC_HELP_STRING([--disable-full-doc], [Omit disabled variables]),
1304 [       if test x$enableval = xno ; then
1305                 full_doc=no
1306         fi
1307 ])
1308 if test x$full_doc != xno ; then
1309   AC_DEFINE(MAKEDOC_FULL,1, [Define if you want complete documentation.])
1310 fi
1311
1312 AC_OUTPUT(Makefile contrib/Makefile doc/Makefile imap/Makefile
1313         intl/Makefile m4/Makefile po/Makefile.in
1314         hcachever.sh muttbug.sh doc/instdoc.sh)