configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl !!! WHEN ADDING NEW CONFIGURE TESTS, PLEASE ADD CODE TO MAIN.C !!!
   4 dnl !!! TO DUMP THEIR RESULTS WHEN MUTT -V IS CALLED            !!!
   5
   6 AC_PREREQ([2.54])
   7 AC_INIT([mutt.h])
   8 AM_CONFIG_HEADER([config.h])
   9
  10 mutt_cv_version=`cat $srcdir/VERSION`
  11 AM_INIT_AUTOMAKE(mutt, $mutt_cv_version)
  12 AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/VERSION'])
  13
  14 AC_GNU_SOURCE
  15
  16 ALL_LINGUAS="de eu ru it es uk fr pl nl cs id sk ko el zh_TW zh_CN pt_BR eo gl sv da lt tr ja hu et ca bg ga"
  17
  18 AC_CANONICAL_HOST
  19
  20 AC_MSG_CHECKING([for prefix])
  21 if test x$prefix = xNONE; then
  22   mutt_cv_prefix=$ac_default_prefix
  23 else
  24   mutt_cv_prefix=$prefix
  25 fi
  26 AC_MSG_RESULT($mutt_cv_prefix)
  27
  28 AC_PROG_CC
  29 AC_ISC_POSIX
  30 AM_C_PROTOTYPES
  31 if test "x$U" != "x"; then
  32   AC_MSG_ERROR(Compiler not ANSI compliant)
  33 fi
  34 AC_PROG_CPP
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(AR, ar, ar)
  39
  40 AC_C_INLINE
  41 AC_C_CONST
  42 AC_C_BIGENDIAN
  43
  44 AC_SYS_LARGEFILE
  45 AC_FUNC_FSEEKO
  46 AC_CHECK_SIZEOF(off_t)
  47
  48 AC_PATH_PROG(DBX, dbx, no)
  49 AC_PATH_PROG(GDB, gdb, no)
  50 AC_PATH_PROG(SDB, sdb, no)
  51
  52 if test $GDB != no ; then
  53         DEBUGGER=$GDB
  54 elif test $DBX != no ; then
  55         DEBUGGER=$DBX
  56 elif test $SDB != no ; then
  57         DEBUGGER=$SDB
  58 else
  59         DEBUGGER=no
  60 fi
  61
  62 AC_SUBST([DEBUGGER])
  63
  64 AH_TEMPLATE([sig_atomic_t],
  65             [/* Define to `int' if <signal.h> doesn't define.])
  66 AH_TEMPLATE([HAVE_START_COLOR],
  67             [Define if you have start_color, as a function or macro.])
  68 AH_TEMPLATE([HAVE_TYPEAHEAD],
  69             [Define if you have typeahead, as a function or macro.])
  70 AH_TEMPLATE([HAVE_BKGDSET],
  71             [Define if you have bkgdset, as a function or macro.])
  72 AH_TEMPLATE([HAVE_CURS_SET],
  73             [Define if you have curs_set, as a function or macro.])
  74 AH_TEMPLATE([HAVE_META],
  75             [Define if you have meta, as a function or macro.])
  76 AH_TEMPLATE([HAVE_USE_DEFAULT_COLORS],
  77             [Define if you have use_default_colors, as a function or macro.])
  78 AH_TEMPLATE([HAVE_RESIZETERM],
  79             [Define if you have resizeterm, as a function or macro.])
  80 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
  81             [Some systems declare sig_atomic_t as volatile, some others -- no.
  82              This define will have value `sig_atomic_t' or
  83              `volatile sig_atomic_t' accordingly.])
  84 AH_TEMPLATE([ICONV_NONTRANS],
  85             [Define as 1 if iconv() only converts exactly and we should treat
  86              all return values other than (size_t)(-1) as equivalent.])
  87
  88 AH_BOTTOM([/* fseeko portability defines */
  89 #ifdef HAVE_FSEEKO
  90 # define LOFF_T off_t
  91 # if HAVE_C99_INTTYPES && HAVE_INTTYPES_H
  92 #  if SIZEOF_OFF_T == 8
  93 #   define OFF_T_FMT "%" PRId64
  94 #  else
  95 #   define OFF_T_FMT "%" PRId32
  96 #  endif
  97 # else
  98 #  if (SIZEOF_OFF_T == 8) && (SIZEOF_LONG == 4)
  99 #   define OFF_T_FMT "%lld"
 100 #  else
 101 #   define OFF_T_FMT "%ld"
 102 #  endif
 103 # endif
 104 #else
 105 # define LOFF_T long
 106 # define fseeko fseek
 107 # define ftello ftell
 108 # define OFF_T_FMT "%ld"
 109 #endif
 110 ])
 111 MUTT_C99_INTTYPES
 112 AC_TYPE_LONG_LONG_INT
 113
 114 ac_aux_path_sendmail=/usr/sbin:/usr/lib
 115 AC_PATH_PROG(SENDMAIL, sendmail, /usr/sbin/sendmail, $PATH:$ac_aux_path_sendmail)
 116 AC_DEFINE_UNQUOTED(SENDMAIL,"$ac_cv_path_SENDMAIL", [Where to find sendmail on your system.])
 117
 118 OPS='$(srcdir)/OPS'
 119
 120 AC_MSG_CHECKING([whether to build with GPGME support])
 121 AC_ARG_ENABLE(gpgme, AC_HELP_STRING([--enable-gpgme], [Enable GPGME support]),
 122 [       if test x$enableval = xyes; then
 123                 enable_gpgme=yes
 124         fi
 125 ])
 126
 127 if test x"$enable_gpgme" = xyes; then
 128    AC_MSG_RESULT(yes)
 129    AM_PATH_GPGME(1.0.0, AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 130                  [Defined, if GPGME support is enabled]),
 131                  [gpgme_found=no])
 132    if test x"$gpgme_found" = xno; then
 133       AC_MSG_ERROR([*** GPGME not found ***])
 134    else
 135       AM_PATH_GPGME(1.1.1, AC_DEFINE(HAVE_GPGME_PKA_TRUST, 1,
 136                                   [Define if GPGME supports PKA]))
 137       #needed to get GPGME_LIBS and al correctly
 138       AM_PATH_GPGME(1.0.0, AC_DEFINE(CRYPT_BACKEND_GPGME, 1,
 139                     [Define if you use GPGME to support OpenPGP]))
 140       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS crypt-gpgme.o crypt-mod-pgp-gpgme.o crypt-mod-smime-gpgme.o"
 141    fi
 142 else
 143    AC_MSG_RESULT([no])
 144 fi
 145
 146 AC_ARG_ENABLE(pgp, AC_HELP_STRING([--disable-pgp], [Disable PGP support]),
 147 [       if test x$enableval = xno ; then
 148                 have_pgp=no
 149         fi
 150 ])
 151
 152 if test x$have_pgp != xno ; then
 153         AC_DEFINE(CRYPT_BACKEND_CLASSIC_PGP,1, [Define if you want classic PGP support.])
 154         PGPAUX_TARGET="pgpring\$(EXEEXT) pgpewrap\$(EXEEXT)"
 155         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pgp.o pgpinvoke.o pgpkey.o pgplib.o gnupgparse.o pgpmicalg.o pgppacket.o crypt-mod-pgp-classic.o"
 156 fi
 157
 158 AC_ARG_ENABLE(smime, AC_HELP_STRING([--disable-smime], [Disable SMIME support]),
 159 [       if test x$enableval = xno ; then
 160                 have_smime=no
 161         fi
 162 ])
 163
 164 if test x$have_smime != xno ; then
 165         AC_DEFINE(CRYPT_BACKEND_CLASSIC_SMIME, 1, [Define if you want clasic S/MIME support.])
 166         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smime.o crypt-mod-smime-classic.o"
 167         SMIMEAUX_TARGET="smime_keys"
 168 fi
 169
 170 AC_ARG_WITH(mixmaster, AC_HELP_STRING([--with-mixmaster@<:@=PATH@:>@], [Include Mixmaster support]),
 171   [if test "$withval" != no
 172    then
 173      if test -x "$withval"
 174      then
 175        MIXMASTER="$withval"
 176      else
 177        MIXMASTER="mixmaster"
 178      fi
 179      OPS="$OPS \$(srcdir)/OPS.MIX"
 180      MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS remailer.o"
 181      AC_DEFINE_UNQUOTED(MIXMASTER,"$MIXMASTER", [Where to find mixmaster on your system.])
 182    fi])
 183
 184 # We now require all OPS
 185 OPS="$OPS \$(srcdir)/OPS.PGP \$(srcdir)/OPS.SMIME \$(srcdir)/OPS.CRYPT "
 186 AC_SUBST([OPS])
 187
 188 AC_SUBST(PGPAUX_TARGET)
 189 AC_SUBST(SMIMEAUX_TARGET)
 190
 191 AC_PATH_PROG(ISPELL, ispell, no)
 192 if test $ISPELL != no; then
 193         AC_DEFINE_UNQUOTED(ISPELL,"$ISPELL",[ Where to find ispell on your system. ])
 194 fi
 195
 196 AC_ARG_WITH(slang, AC_HELP_STRING([--with-slang@<:@=DIR@:>@], [Use S-Lang instead of ncurses]),
 197         [AC_CACHE_CHECK([if this is a BSD system], mutt_cv_bsdish,
 198                 [AC_TRY_RUN([#include <sys/param.h>
 199 #include <stdlib.h>
 200
 201 main ()
 202 {
 203 #ifdef BSD
 204         exit (0);
 205 #else
 206         exit (1);
 207 #endif
 208 }],
 209                         mutt_cv_bsdish=yes,
 210                         mutt_cv_bsdish=no,
 211                         mutt_cv_bsdish=no)])
 212
 213         AC_MSG_CHECKING(for S-Lang)
 214         if test $withval = yes; then
 215                 if test -d $srcdir/../slang; then
 216                         mutt_cv_slang=$srcdir/../slang/src
 217                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 218                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 219                 else
 220                         if test -d $mutt_cv_prefix/include/slang; then
 221                                 CPPFLAGS="$CPPFLAGS -I$mutt_cv_prefix/include/slang"
 222                         elif test -d /usr/include/slang; then
 223                                 CPPFLAGS="$CPPFLAGS -I/usr/include/slang"
 224                         fi
 225                         mutt_cv_slang=yes
 226                 fi
 227         else
 228                 dnl ---Check to see if $withval is a source directory
 229                 if test -f $withval/src/slang.h; then
 230                         mutt_cv_slang=$withval/src
 231                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_slang}"
 232                         LDFLAGS="$LDFLAGS -L${mutt_cv_slang}/objs"
 233                 else
 234                         dnl ---Must be installed somewhere
 235                         mutt_cv_slang=$withval
 236                         if test -d $withval/include/slang; then
 237                                 CPPFLAGS="$CPPFLAGS -I${withval}/include/slang"
 238                         elif test -d $withval/include; then
 239                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 240                         fi
 241                         LDFLAGS="$LDFLAGS -L${withval}/lib"
 242                 fi
 243         fi
 244         AC_MSG_RESULT($mutt_cv_slang)
 245         if test $mutt_cv_bsdish = yes; then
 246                 AC_CHECK_LIB(termlib, main)
 247         fi
 248         AC_DEFINE(USE_SLANG_CURSES,1,
 249                 [ Define if you compile with SLang instead of curses/ncurses. ])
 250         AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 251         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 252
 253         dnl --- now that we've found it, check the link
 254
 255         AC_CHECK_LIB(slang, SLtt_get_terminfo,
 256                 [MUTTLIBS="$MUTTLIBS -lslang -lm"],
 257                 [AC_MSG_ERROR(unable to compile.  check config.log)], -lm)
 258
 259         ],
 260
 261         [mutt_cv_curses=/usr
 262         AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses=DIR], [Where ncurses is installed]),
 263                 [if test $withval != yes; then
 264                         mutt_cv_curses=$withval
 265                 fi
 266                 if test x$mutt_cv_curses != x/usr; then
 267                         LDFLAGS="$LDFLAGS -L${mutt_cv_curses}/lib"
 268                         CPPFLAGS="$CPPFLAGS -I${mutt_cv_curses}/include"
 269                 fi])
 270
 271         AC_CHECK_FUNC(initscr,,[
 272         cf_ncurses="ncurses"
 273         for lib in ncurses ncursesw
 274         do
 275                 AC_CHECK_LIB($lib, waddnwstr, [cf_ncurses="$lib"; break])
 276         done
 277         AC_CHECK_LIB($cf_ncurses, initscr,
 278                 [MUTTLIBS="$MUTTLIBS -l$cf_ncurses"
 279
 280                 if test "$cf_ncurses" = ncursesw; then
 281                         AC_CHECK_HEADERS(ncursesw/ncurses.h,[cf_cv_ncurses_header="ncursesw/ncurses.h"])
 282                 else
 283                   AC_CHECK_HEADERS(ncurses/ncurses.h,[cf_cv_ncurses_header="ncurses/ncurses.h"],
 284                     [AC_CHECK_HEADERS(ncurses.h,[cf_cv_ncurses_header="ncurses.h"])])
 285                 fi],
 286
 287                 [CF_CURSES_LIBS])
 288                 ])
 289
 290         old_LIBS="$LIBS"
 291         LIBS="$LIBS $MUTTLIBS"
 292         CF_CHECK_FUNCDECLS([#include <${cf_cv_ncurses_header-curses.h}>],
 293                            [start_color typeahead bkgdset curs_set meta use_default_colors resizeterm])
 294         if test "$ac_cv_func_decl_start_color" = yes; then
 295                 AC_DEFINE(HAVE_COLOR,1,[ Define if your curses library supports color. ])
 296         fi
 297         if test "$ac_cv_func_decl_resizeterm" = yes; then
 298                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS resize.o"
 299         fi
 300         LIBS="$old_LIBS"
 301         ])
 302
 303 AC_HEADER_STDC
 304
 305 AC_CHECK_HEADERS(stdarg.h sys/ioctl.h ioctl.h sysexits.h)
 306 AC_CHECK_HEADERS(sys/time.h sys/resource.h)
 307 AC_CHECK_HEADERS(unix.h)
 308
 309 AC_CHECK_FUNCS(setrlimit getsid)
 310
 311 AC_TYPE_SIGNAL
 312
 313 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 314 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 315   [
 316     ac_cv_type_sig_atomic_t=yes;
 317     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 318                     signal.h,
 319                     [
 320                         is_sig_atomic_t_volatile=yes;
 321                         AC_MSG_RESULT([yes, volatile])
 322                     ],
 323                     [
 324                         is_sig_atomic_t_volatile=no;
 325                         AC_MSG_RESULT([yes, non volatile])
 326                     ])
 327   ],
 328   [
 329     AC_MSG_RESULT(no)
 330     AC_CHECK_TYPE(sig_atomic_t, int)
 331     is_sig_atomic_t_volatile=no
 332   ])
 333 if test $is_sig_atomic_t_volatile = 'yes'
 334 then
 335     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 336 else
 337     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 338 fi
 339
 340 AC_DECL_SYS_SIGLIST
 341
 342 AC_TYPE_PID_T
 343 AC_CHECK_TYPE(ssize_t, int)
 344
 345 AC_CHECK_FUNCS(fgetpos memmove setegid srand48 strerror)
 346
 347 AC_REPLACE_FUNCS([setenv strcasecmp strdup strsep strtok_r wcscasecmp])
 348 AC_REPLACE_FUNCS([strcasestr mkdtemp])
 349
 350 AC_CHECK_FUNC(getopt)
 351 if test $ac_cv_func_getopt = yes; then
 352         AC_CHECK_HEADERS(getopt.h)
 353 fi
 354
 355 SNPRINTFOBJS=""
 356 AC_CHECK_FUNC(snprintf, [mutt_cv_func_snprintf=yes], [mutt_cv_func_snprintf=no])
 357 AC_CHECK_FUNC(vsnprintf, [mutt_cv_func_vsnprintf=yes], [mutt_cv_func_vsnprintf=no])
 358 if test $mutt_cv_func_snprintf = yes; then
 359 AC_CACHE_CHECK([whether your system's snprintf is C99 compliant],
 360         [mutt_cv_c99_snprintf],
 361         AC_TRY_RUN([
 362 #include <stdio.h>
 363 int main()
 364 {
 365 changequote(, )dnl
 366   char buf[8];
 367   int len = snprintf(buf, 4, "1234567");
 368   return (len != 7 || buf[3] != '\0');
 369 changequote([, ])dnl
 370 }
 371         ], mutt_cv_c99_snprintf=yes, mutt_cv_c99_snprintf=no, mutt_cv_c99_snprintf=no))
 372 else
 373         mutt_cv_c99_snprintf=no
 374 fi
 375 if test $mutt_cv_func_vsnprintf = yes; then
 376 AC_CACHE_CHECK([whether your system's vsnprintf is C99 compliant],
 377         [mutt_cv_c99_vsnprintf],
 378         AC_TRY_RUN([
 379 #include <stdarg.h>
 380 #include <stdio.h>
 381 int foo(const char *fmt, ...)
 382 {
 383 changequote(, )dnl
 384   char buf[8];
 385   int len;
 386   va_list ap;
 387   va_start(ap, fmt);
 388   len = vsnprintf(buf, 4, fmt, ap);
 389   va_end(ap);
 390   return (len != 7 || buf[3] != '\0');
 391 changequote([, ])dnl
 392 }
 393
 394 int main()
 395 {
 396   return foo("%s", "1234567");
 397 }
 398         ], mutt_cv_c99_vsnprintf=yes, mutt_cv_c99_vsnprintf=no, mutt_cv_c99_vsnprintf=no))
 399 else
 400         mutt_cv_c99_vsnprintf=no
 401 fi
 402 if test $mutt_cv_c99_snprintf = yes; then
 403         AC_DEFINE(HAVE_SNPRINTF, 1, [ Define to 1 if you have a C99 compliant snprintf function. ])
 404 fi
 405 if test $mutt_cv_c99_vsnprintf = yes; then
 406         AC_DEFINE(HAVE_VSNPRINTF, 1, [ Define to 1 if you have a C99 compliant vsnprintf function. ])
 407 fi
 408 if test $mutt_cv_c99_snprintf = no -o $mutt_cv_c99_vsnprintf = no; then
 409         AC_LIBOBJ(snprintf)
 410 fi
 411
 412 XIPH_FUNC_VA_COPY
 413
 414 dnl SCO uses chsize() instead of ftruncate()
 415 AC_CHECK_FUNCS(ftruncate, , [AC_CHECK_LIB(x, chsize)])
 416
 417 dnl SCO has strftime() in libintl
 418 AC_CHECK_FUNCS(strftime, , [AC_CHECK_LIB(intl, strftime)])
 419
 420 dnl AIX may not have fchdir()
 421 AC_CHECK_FUNCS(fchdir, , [mutt_cv_fchdir=no])
 422
 423 AC_ARG_WITH(regex, AC_HELP_STRING([--with-regex], [Use the GNU regex library]),
 424         [mutt_cv_regex=yes],
 425         [AC_CHECK_FUNCS(regcomp, mutt_cv_regex=no, mutt_cv_regex=yes)])
 426
 427 if test $mutt_cv_regex = no ; then
 428 AC_CACHE_CHECK([whether your system's regexp library is completely broken],
 429         [mutt_cv_regex_broken],
 430         AC_TRY_RUN([
 431 #include <unistd.h>
 432 #include <regex.h>
 433 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
 434         mutt_cv_regex_broken=no, mutt_cv_regex_broken=yes, mutt_cv_regex_broken=yes))
 435         if test $mutt_cv_regex_broken = yes ; then
 436                 echo "Using the included GNU regex instead." >&AC_FD_MSG
 437                 mutt_cv_regex=yes
 438         fi
 439 fi
 440
 441 if test $mutt_cv_regex = yes; then
 442         AC_DEFINE(USE_GNU_REGEX,1,[ Define if you want to use the included regex.c. ])
 443         AC_LIBOBJ(regex)
 444 fi
 445
 446
 447 AC_ARG_WITH(homespool,
 448   AC_HELP_STRING([--with-homespool@<:@=FILE@:>@], [File in user's directory where new mail is spooled]), with_homespool=${withval})
 449 if test x$with_homespool != x; then
 450         if test $with_homespool = yes; then
 451                 with_homespool=mailbox
 452         fi
 453         AC_DEFINE_UNQUOTED(MAILPATH,"$with_homespool",[ Where new mail is spooled. ])
 454         AC_DEFINE(HOMESPOOL,1,
 455           [Is mail spooled to the user's home directory?  If defined,
 456            MAILPATH should be set to the filename of the spool mailbox
 457            relative the the home directory.
 458            use: configure --with-homespool=FILE])
 459         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 460         mutt_cv_setgid=no
 461 else
 462         AC_ARG_WITH(mailpath, AC_HELP_STRING([--with-mailpath=DIR], [Directory where spool mailboxes are located]),
 463                 [mutt_cv_mailpath=$withval],
 464                 [ AC_CACHE_CHECK(where new mail is stored, mutt_cv_mailpath,
 465                         [mutt_cv_mailpath=no
 466                         if test -d /var/mail; then
 467                                 mutt_cv_mailpath=/var/mail
 468                         elif test -d /var/spool/mail; then
 469                                 mutt_cv_mailpath=/var/spool/mail
 470                         elif test -d /usr/spool/mail; then
 471                                 mutt_cv_mailpath=/usr/spool/mail
 472                         elif test -d /usr/mail; then
 473                                 mutt_cv_mailpath=/usr/mail
 474                         fi])
 475                 ])
 476         if test "$mutt_cv_mailpath" = no; then
 477                 AC_MSG_ERROR("Could not determine where new mail is stored.")
 478         fi
 479         AC_DEFINE_UNQUOTED(MAILPATH,"$mutt_cv_mailpath",[ Where new mail is spooled. ])
 480
 481         AC_CACHE_CHECK(if $mutt_cv_mailpath is world writable, mutt_cv_worldwrite, [AC_TRY_RUN([#include <sys/types.h>
 482 #include <sys/stat.h>
 483 #include <stdlib.h>
 484
 485 int main (int argc, char **argv)
 486 {
 487         struct stat s;
 488
 489         stat ("$mutt_cv_mailpath", &s);
 490         if (s.st_mode & S_IWOTH) exit (0);
 491         exit (1);
 492 }], mutt_cv_worldwrite=yes, mutt_cv_worldwrite=no, mutt_cv_worldwrite=no)])
 493
 494         mutt_cv_setgid=no
 495         if test $mutt_cv_worldwrite = yes; then
 496                 AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 497         else
 498
 499                 AC_CACHE_CHECK(if $mutt_cv_mailpath is group writable, mutt_cv_groupwrite, [AC_TRY_RUN([#include <sys/types.h>
 500 #include <sys/stat.h>
 501 #include <stdlib.h>
 502
 503 int main (int argc, char **argv)
 504 {
 505         struct stat s;
 506
 507         stat ("$mutt_cv_mailpath", &s);
 508         if (s.st_mode & S_IWGRP) exit (0);
 509         exit (1);
 510 }], mutt_cv_groupwrite=yes, mutt_cv_groupwrite=no, mutt_cv_groupwrite=no)])
 511
 512                 if test $mutt_cv_groupwrite = yes; then
 513                         AC_DEFINE(USE_DOTLOCK,1,[ Define to use dotlocking for mailboxes. ])
 514                         AC_DEFINE(USE_SETGID,1,[ Define if mutt should run setgid "mail". ])
 515                         mutt_cv_setgid=yes
 516                 fi
 517         fi
 518 fi
 519
 520 AC_ARG_ENABLE(external_dotlock, AC_HELP_STRING([--enable-external-dotlock], [Force use of an external dotlock program]),
 521         [mutt_cv_external_dotlock="$enableval"])
 522
 523 if test "x$mutt_cv_setgid" = "xyes" || test "x$mutt_cv_fchdir" = "xno" \
 524         || test "x$mutt_cv_external_dotlock" = "xyes"
 525 then
 526         AC_DEFINE(DL_STANDALONE,1,[ Define if you want to use an external dotlocking program. ])
 527         DOTLOCK_TARGET="mutt_dotlock\$(EXEEXT)"
 528 else
 529         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS dotlock.o"
 530 fi
 531
 532 AC_SUBST(DOTLOCK_TARGET)
 533
 534 dnl autoconf <2.60 compatibility
 535 if test -z "$datarootdir"; then
 536   datarootdir='${prefix}/share'
 537 fi
 538 AC_SUBST([datarootdir])
 539
 540 AC_MSG_CHECKING(where to put the documentation)
 541 AC_ARG_WITH(docdir, AC_HELP_STRING([--with-docdir=PATH], [Specify where to put the documentation]),
 542         [mutt_cv_docdir=$withval],
 543         [mutt_cv_docdir='${datarootdir}/doc/mutt'])
 544 AC_MSG_RESULT($mutt_cv_docdir)
 545 if test -z "$docdir" -o -n "$with_docdir"
 546 then
 547   docdir=$mutt_cv_docdir
 548 fi
 549 AC_SUBST(docdir)
 550
 551 if test x$mutt_cv_setgid = xyes; then
 552         DOTLOCK_GROUP='mail'
 553         DOTLOCK_PERMISSION=2755
 554 else
 555         DOTLOCK_GROUP=''
 556         DOTLOCK_PERMISSION=755
 557 fi
 558 AC_SUBST(DOTLOCK_GROUP)
 559 AC_SUBST(DOTLOCK_PERMISSION)
 560
 561 AC_ARG_WITH(domain, AC_HELP_STRING([--with-domain=DOMAIN], [Specify your DNS domain name]),
 562         [if test $withval != yes; then
 563             if test $withval != no; then
 564                 AC_DEFINE_UNQUOTED(DOMAIN,"$withval",[ Define your domain name. ])
 565             fi
 566         fi])
 567
 568 need_socket="no"
 569
 570 dnl -- socket dependencies --
 571
 572 AC_ARG_ENABLE(pop,  AC_HELP_STRING([--enable-pop], [Enable POP3 support]),
 573 [       if test x$enableval = xyes ; then
 574                 AC_DEFINE(USE_POP,1,[ Define if you want support for the POP3 protocol. ])
 575                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS pop.o pop_lib.o pop_auth.o"
 576                 need_pop="yes"
 577                 need_socket="yes"
 578                 need_md5="yes"
 579         fi
 580 ])
 581
 582 AC_ARG_ENABLE(imap, AC_HELP_STRING([--enable-imap], [Enable IMAP support]),
 583 [       if test x$enableval = xyes ; then
 584                 AC_DEFINE(USE_IMAP,1,[ Define if you want support for the IMAP protocol. ])
 585                 LIBIMAP="-Limap -limap"
 586                 LIBIMAPDEPS="\$(top_srcdir)/imap/imap.h imap/libimap.a"
 587                 need_imap="yes"
 588                 need_socket="yes"
 589                 need_md5="yes"
 590         fi
 591 ])
 592 AM_CONDITIONAL(BUILD_IMAP, test x$need_imap = xyes)
 593
 594 AC_ARG_ENABLE(smtp, AC_HELP_STRING([--enable-smtp], [include internal SMTP relay support]),
 595         [if test $enableval = yes; then
 596                 AC_DEFINE(USE_SMTP, 1, [Include internal SMTP relay support])
 597                 MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS smtp.o"
 598                 need_socket="yes"
 599         fi])
 600
 601 if test x"$need_imap" = xyes -o x"$need_pop" = xyes ; then
 602   MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS bcache.o"
 603 fi
 604
 605 dnl -- end socket dependencies --
 606
 607 if test "$need_socket" = "yes"
 608 then
 609         AC_CHECK_HEADERS([sys/select.h])
 610         AC_MSG_CHECKING([for socklen_t])
 611         AC_EGREP_HEADER(socklen_t, sys/socket.h, AC_MSG_RESULT([yes]),
 612                 AC_MSG_RESULT([no])
 613                 AC_DEFINE(socklen_t,int,
 614                         [ Define to 'int' if <sys/socket.h> doesn't have it. ]))
 615         AC_CHECK_FUNC(gethostent, , AC_CHECK_LIB(nsl, gethostent))
 616         AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 617         AC_CHECK_FUNCS(getaddrinfo)
 618         AC_DEFINE(USE_SOCKET,1,
 619                 [ Include code for socket support. Set automatically if you enable POP3 or IMAP ])
 620         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS account.o mutt_socket.o mutt_tunnel.o"
 621 fi
 622
 623 dnl -- imap dependencies --
 624
 625 AC_ARG_WITH(gss, AC_HELP_STRING([--with-gss@<:@=PFX@:>@], [Compile in GSSAPI authentication for IMAP]),
 626     gss_prefix="$withval", gss_prefix="no")
 627 if test "$gss_prefix" != "no"
 628 then
 629   if test "$need_imap" = "yes"
 630   then
 631     MUTT_AM_PATH_GSSAPI(gss_prefix)
 632     AC_MSG_CHECKING(GSSAPI implementation)
 633     AC_MSG_RESULT($GSSAPI_IMPL)
 634     if test "$GSSAPI_IMPL" = "none"
 635     then
 636       AC_CACHE_SAVE
 637       AC_MSG_RESULT([GSSAPI libraries not found])
 638     fi
 639     if test "$GSSAPI_IMPL" = "Heimdal"
 640     then
 641       AC_DEFINE(HAVE_HEIMDAL,1,[ Define if your GSSAPI implementation is Heimdal ])
 642     fi
 643     CPPFLAGS="$CPPFLAGS $GSSAPI_CFLAGS"
 644     MUTTLIBS="$MUTTLIBS $GSSAPI_LIBS"
 645     AC_DEFINE(USE_GSS,1,[ Define if you have GSSAPI libraries available ])
 646     need_gss="yes"
 647   else
 648     AC_MSG_WARN([GSS was requested but IMAP is not enabled])
 649   fi
 650 fi
 651 AM_CONDITIONAL(USE_GSS, test x$need_gss = xyes)
 652
 653 dnl -- end imap dependencies --
 654
 655 AC_ARG_WITH(ssl, AC_HELP_STRING([--with-ssl@<:@=PFX@:>@], [Enable TLS support using OpenSSL]),
 656 [       if test "$with_ssl" != "no"
 657         then
 658           if test "$need_socket" != "yes"; then
 659            AC_MSG_WARN([SSL support is only useful with POP, IMAP or SMTP support])
 660           else
 661             if test "$with_ssl" != "yes"
 662             then
 663              LDFLAGS="$LDFLAGS -L$withval/lib"
 664              CPPFLAGS="$CPPFLAGS -I$withval/include"
 665             fi
 666             saved_LIBS="$LIBS"
 667
 668             crypto_libs=""
 669             AC_CHECK_LIB(z, deflate, [crypto_libs=-lz])
 670             AC_CHECK_LIB(crypto, X509_new,
 671               [crypto_libs="-lcrypto $crypto_libs"],, [$crypto_libs])
 672             AC_CHECK_LIB(ssl, SSL_new,,
 673               AC_MSG_ERROR([Unable to find SSL library]), [$crypto_libs])
 674
 675             LIBS="$LIBS $crypto_libs"
 676             AC_CHECK_FUNCS(RAND_status RAND_egd)
 677
 678             AC_DEFINE(USE_SSL,1,[ Define if you want support for SSL. ])
 679             AC_DEFINE(USE_SSL_OPENSSL,1,[ Define if you want support for SSL via OpenSSL. ])
 680             LIBS="$saved_LIBS"
 681             MUTTLIBS="$MUTTLIBS -lssl $crypto_libs"
 682             MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl.o"
 683             need_ssl=yes
 684           fi
 685         fi
 686 ])
 687
 688 AC_ARG_WITH([gnutls], AC_HELP_STRING([--with-gnutls@<:@=PFX@:>@], [enable TLS support using gnutls]),
 689     [gnutls_prefix="$withval"], [gnutls_prefix="no"])
 690 if test "$gnutls_prefix" != "no" && test x"$need_ssl" != xyes
 691 then
 692   if test "$need_socket" != "yes"
 693   then
 694     AC_MSG_WARN([SSL support is only useful with POP, IMAP or SMTP support])
 695   else
 696     if test "$gnutls_prefix" != "yes"
 697     then
 698       LDFLAGS="$LDFLAGS -L$gnutls_prefix/lib"
 699       CPPFLAGS="$CPPFLAGS -I$gnutls_prefix/include"
 700     fi
 701     saved_LIBS="$LIBS"
 702
 703     AC_CHECK_LIB(gnutls, gnutls_check_version,
 704       [dnl GNUTLS found
 705       AC_CHECK_DECLS([GNUTLS_VERIFY_DISABLE_TIME_CHECKS], [], [],
 706                     [[#include <gnutls/x509.h>]])
 707
 708       LIBS="$saved_LIBS"
 709       MUTTLIBS="$MUTTLIBS -lgnutls"
 710
 711       AC_DEFINE(USE_SSL, 1, [ Define if you want support for SSL. ])
 712       AC_DEFINE(USE_SSL_GNUTLS, 1, [ Define if you want support for SSL via GNUTLS. ])
 713
 714       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_ssl_gnutls.o"
 715       need_ssl=yes],
 716       [AC_MSG_ERROR([could not find libgnutls])])
 717   fi
 718 fi
 719
 720 AM_CONDITIONAL(USE_SSL, test x$need_ssl = xyes)
 721
 722 AC_ARG_WITH(sasl, AC_HELP_STRING([--with-sasl@<:@=PFX@:>@], [Use SASL network security library]),
 723         [
 724         if test "$with_sasl" != "no"
 725         then
 726           if test "$need_socket" != "yes"
 727           then
 728             AC_MSG_ERROR([SASL support is only useful with POP or IMAP support])
 729           fi
 730
 731           if test "$with_sasl" != "yes"
 732           then
 733             CPPFLAGS="$CPPFLAGS -I$with_sasl/include"
 734             LDFLAGS="$LDFLAGS -L$with_sasl/lib"
 735           fi
 736
 737           saved_LIBS="$LIBS"
 738           LIBS=
 739
 740           # OpenSolaris provides a SASL2 interface in libsasl
 741           sasl_libs="sasl2 sasl"
 742           AC_SEARCH_LIBS(sasl_encode64, [$sasl_libs],,
 743                   AC_MSG_ERROR([could not find sasl lib]),)
 744
 745           MUTTLIBS="$MUTTLIBS $LIBS"
 746           MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_sasl.o"
 747           LIBS="$saved_LIBS"
 748
 749           AC_DEFINE(USE_SASL,1,
 750                   [ Define if want to use the SASL library for POP/IMAP authentication. ])
 751           need_sasl=yes
 752         fi
 753         ])
 754 AM_CONDITIONAL(USE_SASL, test x$need_sasl = xyes)
 755
 756 dnl -- end socket --
 757
 758 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging support]),
 759         [ if test x$enableval = xyes ; then
 760                 AC_DEFINE(DEBUG,1,[ Define to enable debugging info. ])
 761           fi
 762          ])
 763
 764 AC_ARG_ENABLE(flock, AC_HELP_STRING([--enable-flock], [Use flock() to lock files]),
 765         [if test $enableval = yes; then
 766                 AC_DEFINE(USE_FLOCK,1, [ Define to use flock() to lock mailboxes. ])
 767         fi])
 768
 769 mutt_cv_fcntl=yes
 770 AC_ARG_ENABLE(fcntl, AC_HELP_STRING([--disable-fcntl], [Do NOT use fcntl() to lock files]),
 771         [if test $enableval = no; then mutt_cv_fcntl=no; fi])
 772
 773 if test $mutt_cv_fcntl = yes; then
 774         AC_DEFINE(USE_FCNTL,1, [ Define to use fcntl() to lock folders. ])
 775 fi
 776
 777 AC_MSG_CHECKING(whether struct dirent defines d_ino)
 778 ac_cv_dirent_d_ino=no
 779 AC_TRY_LINK([#include <dirent.h>],[struct dirent dp; (void)dp.d_ino],[ac_cv_dirent_d_ino=yes])
 780 if test x$ac_cv_dirent_d_ino = xyes ; then
 781   AC_DEFINE(HAVE_DIRENT_D_INO,1,
 782             [Define to 1 if your system has the dirent::d_ino member])
 783 fi
 784 AC_MSG_RESULT($ac_cv_dirent_d_ino)
 785
 786 mutt_cv_warnings=yes
 787 AC_ARG_ENABLE(warnings, AC_HELP_STRING([--disable-warnings], [Turn off compiler warnings (not recommended)]),
 788 [if test $enableval = no; then
 789         mutt_cv_warnings=no
 790 fi])
 791
 792 if test x$GCC = xyes && test $mutt_cv_warnings = yes; then
 793   CFLAGS="-Wall -pedantic -Wno-long-long $CFLAGS"
 794 fi
 795
 796 AC_ARG_ENABLE(nfs-fix, AC_HELP_STRING([--enable-nfs-fix], [Work around an NFS with broken attributes caching]),
 797         [if test x$enableval = xyes; then
 798                 AC_DEFINE(NFS_ATTRIBUTE_HACK,1,
 799                   [Define if you have problems with mutt not detecting
 800                    new/old mailboxes over NFS.  Some NFS implementations
 801                    incorrectly cache the attributes of small files.])
 802         fi])
 803
 804 AC_ARG_ENABLE(mailtool, AC_HELP_STRING([--enable-mailtool], [Enable Sun mailtool attachments support]),
 805         [if test x$enableval = xyes; then
 806                 AC_DEFINE(SUN_ATTACHMENT,1,[ Define to enable Sun mailtool attachments support. ])
 807         fi])
 808
 809 AC_ARG_ENABLE(locales-fix, AC_HELP_STRING([--enable-locales-fix], [The result of isprint() is unreliable]),
 810         [if test x$enableval = xyes; then
 811                 AC_DEFINE(LOCALES_HACK,1,[ Define if the result of isprint() is unreliable. ])
 812         fi])
 813
 814 AC_ARG_WITH(exec-shell, AC_HELP_STRING([--with-exec-shell=SHELL], [Specify alternate shell (ONLY if /bin/sh is broken)]),
 815         [if test $withval != yes; then
 816                 AC_DEFINE_UNQUOTED(EXECSHELL, "$withval",
 817                  [program to use for shell commands])
 818          else
 819                 AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")
 820         fi],
 821         [AC_DEFINE_UNQUOTED(EXECSHELL, "/bin/sh")])
 822
 823 AC_ARG_ENABLE(exact-address, AC_HELP_STRING([--enable-exact-address], [Enable regeneration of email addresses]),
 824         [if test $enableval = yes; then
 825                 AC_DEFINE(EXACT_ADDRESS,1,
 826                   [Enable exact regeneration of email addresses as parsed?
 827                    NOTE: this requires significant more memory when defined.])
 828
 829         fi])
 830
 831 dnl -- start cache --
 832 db_found=no
 833 db_requested=auto
 834 AC_ARG_ENABLE(hcache, AC_HELP_STRING([--enable-hcache],
 835   [Enable header caching]))
 836 AC_ARG_WITH(tokyocabinet, AC_HELP_STRING([--without-tokyocabinet],
 837   [Don't use tokyocabinet even if it is available]))
 838 AC_ARG_WITH(qdbm, AC_HELP_STRING([--without-qdbm],
 839   [Don't use qdbm even if it is available]))
 840 AC_ARG_WITH(gdbm, AC_HELP_STRING([--without-gdbm],
 841   [Don't use gdbm even if it is available]))
 842 AC_ARG_WITH(bdb, AC_HELP_STRING([--with-bdb@<:@=DIR@:>@],
 843   [Use BerkeleyDB4 if gdbm is not available]))
 844
 845 db_found=no
 846 if test x$enable_hcache = xyes
 847 then
 848     AC_DEFINE(USE_HCACHE, 1, [Enable header caching])
 849     MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS hcache.o"
 850
 851     OLDCPPFLAGS="$CPPFLAGS"
 852     OLDLDFLAGS="$LDFLAGS"
 853     OLDLIBS="$LIBS"
 854
 855     need_md5="yes"
 856
 857     if test -n "$with_tokyocabinet" && test "$with_tokyocabinet" != "no"
 858     then
 859       db_requested=tc
 860     fi
 861     if test -n "$with_qdbm" && test "$with_qdbm" != "no"
 862     then
 863       if test "$db_requested" != "auto"
 864       then
 865         AC_MSG_ERROR([more than one header cache engine requested.])
 866       else
 867         db_requested=qdbm
 868       fi
 869     fi
 870     if test -n "$with_gdbm" && test "$with_gdbm" != "no"
 871     then
 872       if test "$db_requested" != "auto"
 873       then
 874         AC_MSG_ERROR([more than one header cache engine requested.])
 875       else
 876         db_requested=gdbm
 877       fi
 878     fi
 879     if test -n "$with_bdb" && test "$with_bdb" != "no"
 880     then
 881       if test "$db_requested" != "auto"
 882       then
 883         AC_MSG_ERROR([more than one header cache engine requested.])
 884       else
 885         db_requested=bdb
 886       fi
 887     fi
 888
 889     dnl -- Tokyo Cabinet --
 890     if test "$with_tokyocabinet" != "no" \
 891             && test "$db_requested" = auto -o "$db_requested" = tc
 892     then
 893       if test -n "$with_tokyocabinet" && test "$with_tokyocabinet" != "yes"
 894       then
 895         CPPFLAGS="$CPPFLAGS -I$with_tokyocabinet/include"
 896         LDFLAGS="$LDFLAGS -L$with_tokyocabinet/lib"
 897       fi
 898
 899       AC_CHECK_HEADER(tcbdb.h,
 900       AC_CHECK_LIB(tokyocabinet, tcbdbopen,
 901         [MUTTLIBS="$MUTTLIBS -ltokyocabinet"
 902          AC_DEFINE(HAVE_TC, 1, [Tokyo Cabinet Support])
 903          db_found=tc],
 904         [CPPFLAGS="$OLDCPPFLAGS"
 905          LDFLAGS="$OLDLDFLAGS"]))
 906       if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 907       then
 908         AC_MSG_ERROR([Tokyo Cabinet could not be used. Check config.log for details.])
 909       fi
 910     fi
 911
 912     dnl -- QDBM --
 913     if test "$with_qdbm" != "no" && test $db_found = no \
 914             && test "$db_requested" = auto -o "$db_requested" = qdbm
 915     then
 916       if test -n "$with_qdbm" && test "$with_qdbm" != "yes"
 917       then
 918         if test -d $with_qdbm/include/qdbm; then
 919           CPPFLAGS="$CPPFLAGS -I$with_qdbm/include/qdbm"
 920         else
 921           CPPFLAGS="$CPPFLAGS -I$with_qdbm/include"
 922         fi
 923         LDFLAGS="$LDFLAGS -L$with_qdbm/lib"
 924       else
 925          if test -d /usr/include/qdbm; then
 926            CPPFLAGS="$CPPFLAGS -I/usr/include/qdbm"
 927          fi
 928       fi
 929
 930       saved_LIBS="$LIBS"
 931       AC_CHECK_HEADERS(villa.h)
 932       AC_CHECK_LIB(qdbm, vlopen,
 933         [MUTTLIBS="$MUTTLIBS -lqdbm"
 934          AC_DEFINE(HAVE_QDBM, 1, [QDBM Support])
 935          db_found=qdbm],
 936         [CPPFLAGS="$OLDCPPFLAGS"
 937          LDFLAGS="$OLDLDFLAGS"])
 938       LIBS="$saved_LIBS"
 939       if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 940       then
 941         AC_MSG_ERROR([QDBM could not be used. Check config.log for details.])
 942       fi
 943     fi
 944
 945     dnl -- GDBM --
 946     if test x$with_gdbm != xno && test $db_found = no \
 947             && test "$db_requested" = auto -o "$db_requested" = gdbm
 948     then
 949         if test "$with_gdbm" != "yes"
 950         then
 951           CPPFLAGS="$CPPFLAGS -I$with_gdbm/include"
 952           LDFLAGS="$LDFLAGS -L$with_gdbm/lib"
 953         fi
 954         saved_LIBS="$LIBS"
 955         LIBS="$LIBS -lgdbm"
 956         AC_CACHE_CHECK(for gdbm_open, ac_cv_gdbmopen,[
 957             ac_cv_gdbmopen=no
 958             AC_TRY_LINK([#include <gdbm.h>],[gdbm_open(0,0,0,0,0);],[ac_cv_gdbmopen=yes])
 959         ])
 960         LIBS="$saved_LIBS"
 961         if test "$ac_cv_gdbmopen" = yes
 962         then
 963           AC_DEFINE(HAVE_GDBM, 1, [GDBM Support])
 964           MUTTLIBS="$MUTTLIBS -lgdbm"
 965           db_found=gdbm
 966         fi
 967         if test "$db_requested" != auto && test "$db_found" != "$db_requested"
 968         then
 969           AC_MSG_ERROR([GDBM could not be used. Check config.log for details.])
 970         fi
 971     fi
 972
 973     dnl -- BDB --
 974     ac_bdb_prefix="$with_bdb"
 975     if test x$ac_bdb_prefix != xno && test $db_found = no
 976     then
 977         if test x$ac_bdb_prefix = xyes || test x$ac_bdb_prefix = x
 978         then
 979           ac_bdb_prefix="$mutt_cv_prefix /opt/csw/bdb4 /opt /usr/local /usr"
 980         fi
 981         for d in $ac_bdb_prefix; do
 982             bdbpfx="$bdbpfx $d"
 983             for v in BerkeleyDB.4.3 BerkeleyDB.4.2 BerkeleyDB.4.1; do
 984                 bdbpfx="$bdbpfx $d/$v"
 985             done
 986         done
 987         BDB_VERSIONS="db-4 db4 db-4.6 db4.6 db46 db-4.5 db4.5 db45 db-4.4 db4.4 db44 db-4.3 db4.3 db43 db-4.2 db4.2 db42 db-4.1 db4.1 db41 db ''"
 988         AC_MSG_CHECKING([for BerkeleyDB > 4.0])
 989         for d in $bdbpfx; do
 990             BDB_INCLUDE_DIR=""
 991             BDB_LIB_DIR=""
 992             for v in / $BDB_VERSIONS; do
 993                 if test -r "$d/include/$v/db.h"; then
 994                     BDB_INCLUDE_DIR="$d/include/$v"
 995                     for bdblibdir in "$d/lib/$v" "$d/lib"; do
 996                         test -d "$bdblibdir" || continue
 997                         BDB_LIB_DIR="$bdblibdir"
 998                         for l in `echo $BDB_VERSIONS`; do
 999                             CPPFLAGS="$OLDCPPFLAGS -I$BDB_INCLUDE_DIR"
1000                             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$l"
1001                             AC_TRY_LINK([
1002                                 #include <stdlib.h>
1003                                 #include <db.h>
1004                             ],[
1005                                 DB *db = NULL;
1006                                 db->open(db,NULL,NULL,NULL,0,0,0);
1007                             ],[
1008                                 ac_cv_dbcreate=yes
1009                                 BDB_LIB="$l"
1010                                 break
1011                             ])
1012                         done
1013                         test x$ac_cv_dbcreate = xyes && break 2
1014                     done
1015                 fi
1016             done
1017             test x$BDB_LIB != x && break
1018         done
1019         if test x$ac_cv_dbcreate = xyes
1020         then
1021             AC_MSG_RESULT(yes)
1022             CPPFLAGS="$OLDCPPFLAGS -I$BDB_INCLUDE_DIR"
1023             LIBS="$OLDLIBS -L$BDB_LIB_DIR -l$BDB_LIB"
1024             AC_DEFINE(HAVE_DB4, 1, [Berkeley DB4 Support])
1025             db_found=bdb
1026         else
1027             AC_MSG_RESULT(no)
1028         fi
1029     fi
1030
1031     if test $db_found = no
1032     then
1033         AC_MSG_ERROR([You need Tokyo Cabinet, QDBM, GDBM or Berkeley DB4 for hcache])
1034     fi
1035 fi
1036 dnl -- end cache --
1037
1038 AM_CONDITIONAL(BUILD_HCACHE, test x$db_found != xno)
1039
1040 if test "$need_md5" = "yes"
1041 then
1042   MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS md5.o"
1043 fi
1044
1045 if test x$db_found != xno ; then
1046   MUTT_MD5="mutt_md5$EXEEXT"
1047 fi
1048 AC_SUBST(MUTT_MD5)
1049
1050 AC_SUBST(MUTTLIBS)
1051 AC_SUBST(MUTT_LIB_OBJECTS)
1052 AC_SUBST(LIBIMAP)
1053 AC_SUBST(LIBIMAPDEPS)
1054
1055 dnl -- iconv/gettext --
1056
1057 AC_ARG_ENABLE(iconv, AC_HELP_STRING([--disable-iconv], [Disable iconv support]),
1058         [if test x$enableval = xno ; then
1059                 am_cv_func_iconv=no
1060         fi
1061 ])
1062
1063 MUTT_AM_GNU_GETTEXT
1064
1065 if test "$am_cv_func_iconv" != "yes"
1066 then
1067   AC_MSG_WARN([Configuring without iconv support. See INSTALL for details])
1068 else
1069
1070 AC_CHECK_HEADERS(iconv.h,
1071         [AC_MSG_CHECKING(whether iconv.h defines iconv_t)
1072          AC_EGREP_HEADER([typedef.*iconv_t],iconv.h,
1073                 [AC_MSG_RESULT(yes)
1074                  AC_DEFINE(HAVE_ICONV_T_DEF, 1,
1075                         [Define if <iconv.h> defines iconv_t.])],
1076                  AC_MSG_RESULT(no))])
1077
1078 dnl (1) Some implementations of iconv won't convert from UTF-8 to UTF-8.
1079 dnl (2) In glibc-2.1.2 and earlier there is a bug that messes up ob and
1080 dnl     obl when args 2 and 3 are 0 (fixed in glibc-2.1.3).
1081 AC_CACHE_CHECK([whether this iconv is good enough], mutt_cv_iconv_good,
1082         mutt_save_LIBS="$LIBS"
1083         LIBS="$LIBS $LIBICONV"
1084         AC_TRY_RUN([
1085 #include <iconv.h>
1086 int main()
1087 {
1088   iconv_t cd;
1089 changequote(, )dnl
1090   char buf[4];
1091 changequote([, ])dnl
1092   char *ob;
1093   size_t obl;
1094   ob = buf, obl = sizeof(buf);
1095   return ((cd = iconv_open("UTF-8", "UTF-8")) != (iconv_t)(-1) &&
1096           (iconv(cd, 0, 0, &ob, &obl) ||
1097            !(ob == buf && obl == sizeof(buf)) ||
1098            iconv_close(cd)));
1099 }
1100                 ],
1101                 mutt_cv_iconv_good=yes,
1102                 mutt_cv_iconv_good=no,
1103                 mutt_cv_iconv_good=yes)
1104         LIBS="$mutt_save_LIBS")
1105 if test "$mutt_cv_iconv_good" = no; then
1106   AC_MSG_ERROR(Try using libiconv instead)
1107 fi
1108
1109 dnl This is to detect implementations such as the one in glibc-2.1,
1110 dnl which always convert exactly but return the number of characters
1111 dnl converted instead of the number converted inexactly.
1112 AC_CACHE_CHECK([whether iconv is non-transcribing], mutt_cv_iconv_nontrans,
1113         mutt_save_LIBS="$LIBS"
1114         LIBS="$LIBS $LIBICONV"
1115         AC_TRY_RUN([
1116 #include <iconv.h>
1117 #include <string.h>
1118 int main()
1119 {
1120   iconv_t cd;
1121   const char *ib;
1122   char *ob;
1123   size_t ibl, obl;
1124   const char *s = "\304\211";
1125 changequote(, )dnl
1126   char t[3];
1127 changequote([, ])dnl
1128   ib = s, ibl = 2, ob = t, obl = 3;
1129   return ((cd = iconv_open("UTF-8", "UTF-8")) == (iconv_t)(-1) ||
1130           iconv(cd, &ib, &ibl, &ob, &obl));
1131 }
1132                 ],
1133                 mutt_cv_iconv_nontrans=no,
1134                 mutt_cv_iconv_nontrans=yes,
1135                 mutt_cv_iconv_nontrans=no)
1136         LIBS="$mutt_save_LIBS")
1137 if test "$mutt_cv_iconv_nontrans" = yes; then
1138   AC_DEFINE(ICONV_NONTRANS, 1)
1139 else
1140   AC_DEFINE(ICONV_NONTRANS, 0)
1141 fi
1142
1143 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/intl"
1144
1145 if test "$BUILD_INCLUDED_LIBINTL" = "yes"; then
1146   AC_DEFINE(HAVE_BIND_TEXTDOMAIN_CODESET,1,
1147           [ Define if your gettext has bind_textdomain_codeset. ])
1148 else
1149   mutt_save_LIBS="$LIBS"
1150   LIBS="$LIBS $INTLLIBS"
1151   AC_CHECK_FUNCS(bind_textdomain_codeset)
1152   LIBS="$mutt_save_LIBS"
1153 fi
1154
1155 fi # libiconv
1156
1157 dnl -- IDN depends on iconv
1158
1159 AC_ARG_WITH(idn, AC_HELP_STRING([--with-idn=@<:@PFX@:>@], [Use GNU libidn for domain names]),
1160                  [
1161                   if test "$with_idn" != "no" ; then
1162                         if test "$with_idn" != "yes" ; then
1163                            CPPFLAGS="$CPPFLAGS -I$with_idn/include"
1164                            LDFLAGS="$LDFLAGS -L$with_idn/lib"
1165                         fi
1166                   fi
1167                  ]
1168 )
1169
1170 if test "x$with_idn" != "xno"; then
1171   if test "$am_cv_func_iconv" != "yes"
1172   then
1173     if test "x$with_idn" != "x"
1174     then
1175       AC_MSG_ERROR([IDN requested but iconv is disabled or unavailable])
1176     fi
1177   else
1178     AC_SEARCH_LIBS([stringprep_check_version], [idn], [
1179       AC_DEFINE([HAVE_LIBIDN], 1, [Define to 1 if you have the `idn' library])
1180       MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS mutt_idna.o"
1181     ])
1182     AC_CHECK_FUNCS(idna_to_unicode_utf8_from_utf8 idna_to_unicode_8z8z)
1183     AC_CHECK_FUNCS(idna_to_ascii_from_utf8 idna_to_ascii_8z)
1184     AC_CHECK_FUNCS(idna_to_ascii_lz idna_to_ascii_from_locale)
1185   fi
1186 fi
1187
1188 dnl -- locales --
1189
1190 AC_CHECK_HEADERS(wchar.h)
1191
1192 AC_CACHE_CHECK([for wchar_t], mutt_cv_wchar_t,
1193         AC_TRY_COMPILE([
1194 #include <stddef.h>
1195 #include <stdlib.h>
1196 #ifdef HAVE_WCHAR_H
1197 #include <wchar.h>
1198 #endif
1199                 ],
1200                 [ wchar_t wc; return 0; ],
1201                 mutt_cv_wchar_t=yes,
1202                 mutt_cv_wchar_t=no))
1203
1204 if test "$mutt_cv_wchar_t" = no; then
1205         AC_DEFINE(wchar_t,int,[ Define to 'int' if system headers don't define. ])
1206 fi
1207
1208 AC_CACHE_CHECK([for wint_t], mutt_cv_wint_t,
1209         AC_TRY_COMPILE([
1210 #include <stddef.h>
1211 #include <stdlib.h>
1212 #ifdef HAVE_WCHAR_H
1213 #include <wchar.h>
1214 #endif
1215                 ],
1216                 [ wint_t wc; return 0; ],
1217                 mutt_cv_wint_t=yes,
1218                 mutt_cv_wint_t=no))
1219
1220 if test "$mutt_cv_wint_t" = no; then
1221         AC_DEFINE(wint_t,int,[ Define to 'int' if system headers don't define. ])
1222 fi
1223
1224 AC_CHECK_HEADERS(wctype.h)
1225 AC_CHECK_FUNCS(iswalnum iswalpha iswblank iswcntrl iswdigit)
1226 AC_CHECK_FUNCS(iswgraph iswlower iswprint iswpunct iswspace iswupper)
1227 AC_CHECK_FUNCS(iswxdigit towupper towlower)
1228
1229 AC_CACHE_CHECK([for mbstate_t], mutt_cv_mbstate_t,
1230         AC_TRY_COMPILE([
1231 #include <stddef.h>
1232 #include <stdlib.h>
1233 #ifdef HAVE_WCHAR_H
1234 #include <wchar.h>
1235 #endif
1236                 ],
1237                 [ mbstate_t s; return 0; ],
1238                 mutt_cv_mbstate_t=yes,
1239                 mutt_cv_mbstate_t=no))
1240
1241 if test "$mutt_cv_mbstate_t" = no; then
1242         AC_DEFINE(mbstate_t,int,[ Define to 'int' if system headers don't define. ])
1243 fi
1244
1245 wc_funcs=maybe
1246 AC_ARG_WITH(wc-funcs, AC_HELP_STRING([--without-wc-funcs], [Do not use the system's wchar_t functions]),
1247         wc_funcs=$withval)
1248
1249 if test "$wc_funcs" != yes && test "$wc_funcs" != no; then
1250         AC_CACHE_CHECK([for wchar_t functions], mutt_cv_wc_funcs,
1251                 mutt_cv_wc_funcs=no
1252                 AC_TRY_LINK([
1253 #define _XOPEN_SOURCE 600
1254 #include <stddef.h>
1255 #include <stdlib.h>
1256 #ifdef HAVE_WCHAR_H
1257 #include <wchar.h>
1258 #endif
1259 #ifdef HAVE_WCTYPE_H
1260 #include <wctype.h>
1261 #endif],
1262                         [mbrtowc(0, 0, 0, 0); wctomb(0, 0); wcwidth(0);
1263         iswprint(0); iswspace(0); towlower(0); towupper(0); iswalnum(0)],
1264                         mutt_cv_wc_funcs=yes))
1265         wc_funcs=$mutt_cv_wc_funcs
1266 fi
1267
1268 if test $wc_funcs = yes; then
1269         AC_DEFINE(HAVE_WC_FUNCS,1,[ Define if you are using the system's wchar_t functions. ])
1270 else
1271         MUTT_LIB_OBJECTS="$MUTT_LIB_OBJECTS utf8.o wcwidth.o"
1272 fi
1273
1274 AC_CACHE_CHECK([for nl_langinfo and CODESET], mutt_cv_langinfo_codeset,
1275   [AC_TRY_LINK([#include <langinfo.h>],
1276     [char* cs = nl_langinfo(CODESET);],
1277     mutt_cv_langinfo_codeset=yes,
1278     mutt_cv_langinfo_codeset=no)])
1279 if test $mutt_cv_langinfo_codeset = yes; then
1280   AC_DEFINE(HAVE_LANGINFO_CODESET,1,[ Define if you have <langinfo.h> and nl_langinfo(CODESET). ])
1281 fi
1282
1283 AC_CACHE_CHECK([for nl_langinfo and YESEXPR], mutt_cv_langinfo_yesexpr,
1284   [AC_TRY_LINK([#include <langinfo.h>],
1285     [char* cs = nl_langinfo(YESEXPR);],
1286     mutt_cv_langinfo_yesexpr=yes,
1287     mutt_cv_langinfo_yesexpr=no)])
1288 if test $mutt_cv_langinfo_yesexpr = yes; then
1289   AC_DEFINE(HAVE_LANGINFO_YESEXPR,1,[ Define if you have <langinfo.h> and nl_langinfo(YESEXPR). ])
1290 fi
1291
1292 dnl Documentation tools
1293 have_openjade="no"
1294 AC_PATH_PROG([OSPCAT], [ospcat], [none])
1295 if test "$OSPCAT" != "none"
1296 then
1297   AC_MSG_CHECKING([for openjade docbook stylesheets])
1298   dslosfile=`ospcat --public-id="-//Norman Walsh//DOCUMENT DocBook Print Stylesheet//EN"`
1299   DSLROOT=`echo $dslosfile | sed -n -e "s/.*SOIBASE='\(@<:@^'@:>@*\)\/catalog'.*/\1/p"`
1300   # ospcat may spit out an absolute path without an SOIBASE
1301   if test -z "$DSLROOT"
1302   then
1303     DSLROOT=`echo $dslosfile | sed -e 's|<OSFILE>\(.*\)/print/docbook.dsl|\1|'`
1304   fi
1305   if test -f $DSLROOT/print/docbook.dsl
1306   then
1307     AC_MSG_RESULT([in $DSLROOT])
1308     have_openjade="yes"
1309   else
1310     AC_MSG_RESULT([not found: PDF documentation will not be built.])
1311   fi
1312 fi
1313 AC_SUBST(DSLROOT)
1314
1315 AC_ARG_ENABLE(full_doc,
1316               AC_HELP_STRING([--disable-full-doc], [Omit disabled variables]),
1317 [       if test x$enableval = xno ; then
1318                 full_doc=no
1319         fi
1320 ])
1321 if test x$full_doc != xno ; then
1322   AC_DEFINE(MAKEDOC_FULL,1, [Define if you want complete documentation.])
1323 fi
1324
1325 AC_OUTPUT(Makefile contrib/Makefile doc/Makefile imap/Makefile
1326         intl/Makefile m4/Makefile po/Makefile.in
1327         hcachever.sh muttbug.sh doc/instdoc.sh)